Get @:enum abstract values

Main.hx

import haxe.macro.Context;
import haxe.macro.Expr;

using haxe.macro.Tools;

@:enum abstract MyEnum(Int) {
    var A = 1;
    var B = 2;
    var C = 3;
}

class Main {
    static function main() {
        trace(enums(MyEnum));
    }

    static macro function enums(e) {
        var path = e.toString();
        var type = Context.getType(path);
        switch (type.follow()) {
            case TAbstract(_.get() => ab, _) if (ab.meta.has(":enum")):
                var ct = type.toComplexType();
                var values = [];
                for (f in ab.impl.get().statics.get())
                {
                    if (!(f.meta.has(":enum") && f.meta.has(":impl")))
                        continue;
                    var expr = Context.getTypedExpr(f.expr());
                    values.push(macro ($expr : $ct));
                }
                return macro $a{values};
            default:
                throw new Error(type.toString() + " should be @:enum abstract", e.pos);
        }

    }
}