IsNil Ash validation (validate the fields are nil)

gistfile1.txt

defmodule MyApp.Validation.IsNil do
  use Ash.Resource.Validation
  alias Ash.Error.Changes.{NoSuchAttribute, InvalidAttribute}

  @impl true
  def init(opts) do
    {:ok, opts}
  end

  @impl true
  def validate(changeset, opts) do
    fields = Keyword.get(opts, :fields)

    errors =
      fields
      |> Enum.reduce([], fn field, errors ->
        case changeset.data |> Map.has_key?(field) do
          false ->
            error =
              [resource: changeset.resource, name: field]
              |> with_description(opts)
              |> NoSuchAttribute.exception()

            [error | errors]

          true ->
            case changeset.data |> Map.get(field) do
              nil ->
                errors

              _ ->
                error =
                  [field: field, value: Ash.Changeset.get_attribute(changeset, field)]
                  |> with_description(opts)
                  |> InvalidAttribute.exception()

                [error | errors]
            end
        end
      end)
      |> Enum.reverse()

    case errors do
      [] -> :ok
      errors -> {:error, errors}
    end
  end
end