id_generator.lol

HAI 1.4
  CAN HAS STRING?

  I HAS A alpha_chars ITZ "abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ1234567890"

  I HAS A length
  length R I IZ STRING'Z LEN YR alpha_chars MKAY

  I HAS A counter ITZ 1
  HOW IZ I rng YR number
    I HAS A thing ITZ MAEK number A NUMBR
    IM IN YR LOOP UPPIN YR ROUNDS WILE DIFFRINT ROUNDS AN number
      thing R MOD OF PRODUKT OF 75 AN SUM OF thing AN counter AN 65537
      counter R SUM OF counter AN 1
    IM OUTTA YR LOOP
    FOUND YR MOD OF thing AN number
  IF U SAY SO

  HOW IZ I generate_id YR prefix AN YR seed
    I HAS A id ITZ MAEK SMOOSH prefix AN "_" MKAY A YARN

    IM IN YR loop UPPIN YR index TIL BOTH SAEM index AN 24
      I HAS A number ITZ MAEK I IZ rng YR SUM OF seed AN index MKAY A NUMBR

      I HAS A char ITZ I IZ STRING'Z AT YR alpha_chars AN YR MOD OF number AN length MKAY

      id R SMOOSH id AN char MKAY
    IM OUTTA YR loop

    FOUND YR id
  IF U SAY SO

  I HAS A seed ITZ A NUMBR

  VISIBLE "Random number seed: "!
  GIMMEH seed

  VISIBLE ":)Random ID: "!

  VISIBLE I IZ generate_id YR "user" AN YR seed MKAY
KTHXBYE