PKGBUILD for ProDy

prody.PKGBUILD

# Maintainer: Tomasz Zok <tomasz.zok@gmail.com>
pkgbase=python-prody
pkgname=('python2-prody' 'python-prody')
pkgver=1.5.1
pkgrel=2
pkgdesc="Protein Dynamics & Sequence Analysis"
arch=(any)
url="http://www.csb.pitt.edu/prody/"
license=('GPLv3')
makedepends=('python>=2.7' 'python3' 'python-setuptools' 'python2-setuptools')
source=(http://pypi.python.org/packages/source/P/ProDy/ProDy-$pkgver.tar.gz)
md5sums=('30bfbc8566269d4c9eb5998ba9025728')

prepare() {
  cp -a "$srcdir/ProDy-$pkgver" "$srcdir/python2-ProDy-$pkgver"
  mv "$srcdir/ProDy-$pkgver" "$srcdir/python-ProDy-$pkgver"
}

build() {
  echo "Building Python2"
  cd "$srcdir/python2-ProDy-$pkgver"
  python2 setup.py build

  echo "Building Python3"
  cd "$srcdir/python-ProDy-$pkgver"
  python setup.py build
}

package_generic() {
  pyver=${1}
  depends=("python${pyver}" "python${pyver}-numpy>=1.4")
  provides=("python${pyver}-prody=${pkgver}")
  replaces=("python${pyver}-prody")
  conflicts=("python${pyver}-prody")

  cd "$srcdir/python${pyver}-ProDy-$pkgver"
  mkdir -p "$pkgdir/usr/"
  python${pyver} setup.py install --prefix "$pkgdir/usr/"

  if [[ "x${pyver}" != "x" ]]; then
    mv "$pkgdir/usr/bin/evol"  "$pkgdir/usr/bin/evol${pyver}"
    mv "$pkgdir/usr/bin/prody" "$pkgdir/usr/bin/prody${pyver}"
  fi
}

package_python2-prody() {
  package_generic 2
}

package_python-prody() {
  package_generic
}

# vim:set ts=2 sw=2 et: