Clark Stanley's All-Natural Organic Factory Gears (PuzzleScript Script)

readme.txt

Play this game by pasting the script in http://www.puzzlescript.net/editor.html

script.txt

(sort of a homage to the ps game "unconventional guns", particularly with the scene that depicts the snake oil gun close up: http://www.puzzlescript.net/play.html?p=f4959a4150da120e6117a8c4e7c1a69d )

title Clark Stanley's All-Natural Organic Factory Gears
author My Name Here
homepage www.puzzlescript.net
verbose_logging
youtube 7CLPLAg0ZBA
again_interval 0.08
========
OBJECTS
========

Background 
#4c4c4f #505055
01000
01000
01000
11111
01000

Target1
Red
.0.0.
0...0
..0..
0...0
.0.0.

Target2
Red
0.0.0
.....
0.0.0
.....
0.0.0

Wall 
Darkgray Gray #828290
10002
01120
01200
02000
20001

PlayernogunD
Orange Brown Darkbrown Black
.111.
22222
.303.
.010.
.212.

PlayernogunR
Orange Brown Darkbrown Black
.111.
22222
.003.
.001.
..22.

PlayernogunU
Orange Brown Darkbrown Black
.111.
22222
.000.
.000.
.212.

PlayernogunL
Orange Brown Darkbrown Black
.111.
22222
.300.
.100.
.22..

PlayergunD
Orange Brown Darkbrown Black Gray Darkgray
.111.
22222
4303.
5010.
.212.

PlayergunR
Orange Brown Darkbrown Black Gray Darkgray
.111.
22222
.0044
.005.
..22.

PlayergunU
Orange Brown Darkbrown Black Gray Darkgray
.111.
22222
.0004
.0005
.212.

PlayergunL
Orange Brown Darkbrown Black Darkgray
.111.
22222
4300.
.100.
.22..

playerfaceplantd
brown darkbrown
.....
.111.
10001
10001
10001

playerfaceplantr
orange brown darkbrown black
.....
...2.
.0021
20021
21321

playerfaceplantl
orange brown darkbrown black
.....
.2...
1200.
12002
12312

playerfaceplantu
orange brown darkbrown black
.....
.222.
20002
21012
21012

Crate1
Lightgray Gray
0.0.1
.001.
00.11
.011.
1.1.1

Crate2
Lightgray Gray
.0.0.
00011
.0.1.
00111
.1.1.

Snakeoil S
yellow lightbrown
10011
01100
10001
00110
11001

Spikes
white lightgray gray
.....
.0.1.
..0..
.1.2.
.....

marker
purple
....0
.....
..0..
.....
0....

oilmarker
darkbrown
.....
.....
..0..
.....
.....

oilmarkerlead
darkbrown brown
.....
..0..
.010.
..0..
.....

oilgun
gray darkgray
.....
.....
..00.
..1..
.....

gunscene1 1
#4c4c4f

gunscene2 2
gray

gunscene3 3
darkgray

Catwalk ,
#002 #4c4c4f
01000
01000
01000
11111
01000

entrance e
blue
00000
0....
00000
0....
00000

=======
LEGEND
=======

. = Background
# = Wall
P = PlayernogunD
Q = playergund
* = Crate1
! = crate2
@ = Crate1 and Target1
O = Target1
G = Target2
playernogun = playernogund or playernogunr or playernogunu or playernogunl
playergun = PlayergunD or PlayergunR or PlayergunU or PlayergunL
playerfaceplant = playerfaceplantd or playerfaceplantr or playerfaceplantl or playerfaceplantu
player = playernogun or playergun or playerfaceplant
playerr = playergunr or playernogunr or playerfaceplantr
playeru = playergunu or playernogunu or playerfaceplantu
playerd = playergund or playernogund or playerfaceplantd
playerl = playergunl or playernogunl or playerfaceplantl
playeralive = playernogun or playergun
crate = crate1 or crate2
target = target1 or target2
k = spikes
? = oilgun
b = PlayernogunD and target1
d = playergund and e

=======
SOUNDS
=======

sfx0 62725303
sfx1 90982307
playerfaceplant create 21978903 (50328905)
playerfaceplant create 30625907

================
COLLISIONLAYERS
================

marker
e
Background
Catwalk
snakeoil, gunscene1, gunscene2, gunscene3
spikes
Target, Oilgun
oilmarker
oilmarkerlead
Player, Wall, Crate

======
RULES     
======     

[e oilmarker] -> [e action oilmarker]
[e oilmarkerlead] -> [snakeoil e oilmarker] again

[> playerfaceplant|no marker] -> cancel
[action playerfaceplant] -> cancel
[marker crate|marker crate] -> [crate|crate]

late [oilmarkerlead wall] -> [wall]
late [oilmarkerlead snakeoil] -> [snakeoil]
[oilmarker no e] -> [action oilmarker]
[action oilmarker|oilmarkerlead] -> [oilmarker|oilmarkerlead]
[action oilmarker] -> []
[Snakeoil] -> [snakeoil no Background]

[left playernogun] -> [left playernogunl]
[right playernogun] -> [right playernogunr]
[up playernogun] -> [up playernogunu]
[down playernogun] -> [down playernogund]

[left playergun] -> [left playergunl]
[right playergun] -> [right playergunr]
[up playergun] -> [up playergunu]
[down playergun] -> [down playergund]

[ >  Player | Crate|no crate no wall ] -> [  >  Player | > Crate|  ]  sfx1    


[> crate|crate] -> [crate|crate]
[> crate|wall] -> [crate|wall]

[> crate1 Background] -> [> crate2 no Background]
[> crate2 Background] -> [> crate1 no Background]

right [action playergunr|no wall] -> [playergunr oilmarker|action oilmarkerlead] sfx0 again
down [action playergund|no wall] -> [playergund oilmarker|action oilmarkerlead] sfx0 again
up [action playergunu|no wall] -> [playergunu oilmarker|action oilmarkerlead] sfx0 again
left [action playergunl|no wall] -> [playergunl oilmarker|action oilmarkerlead] sfx0 again

[oilmarker no player|stationary oilmarkerlead no wall|] -> [snakeoil|snakeoil oilmarker|action oilmarkerlead] again
[oilmarker player|stationary oilmarkerlead no wall|] -> [player|snakeoil oilmarker|action oilmarkerlead] again

[PlayerR snakeoil] -> [right playerr snakeoil] again
[Playerl snakeoil] -> [left playerl snakeoil] again
[Playeru snakeoil] -> [up playeru snakeoil] again
[Playerd snakeoil] -> [down playerd snakeoil] again
[marker crate snakeoil|marker|] -> [> crate snakeoil|marker|marker] again
+[marker crate|marker crate] -> [crate|crate]
[stationary crate marker snakeoil|marker] -> [> crate snakeoil|] again
[marker] -> []

[ >  Player | stationary Crate|no crate no wall ] -> [  >  Player | > Crate|  ]  sfx1  

[> crate|crate] -> [crate|crate]
[> crate|wall] -> [crate|wall]

[> crate1 Background] -> [> crate2 no Background]
[> crate2 Background] -> [> crate1 no Background]
[no Background no Snakeoil] -> [Background]   

[> Player|snakeoil] -> [> player|snakeoil] again
[> crate|snakeoil|] -> [> crate|marker snakeoil|marker] again

late [playeru no playerfaceplantu spikes] -> [playerfaceplantu spikes]
late [playerd no playerfaceplantd spikes] -> [playerfaceplantd spikes]
late [playerr no playerfaceplantr spikes] -> [playerfaceplantr spikes]
late [playerl no playerfaceplantl spikes] -> [playerfaceplantl spikes]

late [playernogunr oilgun] -> [playergunr] win
late [playernogund oilgun] -> [playergund] win
late [playernogunu oilgun] -> [playergunu] win
late [playernogunl oilgun] -> [playergunl] win

[gunscene1] -> win
late [snakeoil catwalk] -> [catwalk]

==============
WINCONDITIONS
==============

All Target1 on Crate1  
all target2 on crate2
some target
no marker
some playeralive

=======     
LEVELS
=======

message Much better than those nasty factory-built factory gears.

#######
###..##
#....##
#..#o.#
##...*p
##..###
#######

######*
p...o##
#.#.*.#
#.*.#.#
##o...#
*######

message Just make sure you slot them in right.

######!
p...o.#
#.#.!.#
#.!.#.#
##o...#
!######

message All natural snake oil! Just lying here!
message Someone could be making a living off of this stuff, provided they don't slip and fall on it.

#########
#..sss..#
#..sss..#
#o*.s.*o#
#..sss..#
p..sss..#
#########

#########
####..###
#.......#
po**ss*o#
#.......#
####..###
#########

#kkkkkkkk#
osss.s.ssk
!ss.sss.sk
.ssss.sssk
ks.sss.ssk
kss.s.ss.k
#s.s.ss.sk
psssss.ssk
#kkkkkkkk#

message Hello, what's this?

###p###
#.....#
#.....#
#..?..#
#.....#
#######

3231111132
2311112213
3111222221
1122222211
1222223111
1222231111
1123311111
1113331113
3111331132
2311111323

message It's some type of newfangled laser beam weaponry...
message (Press space to fire)

####d####
#.......#
#.!...o.#
#.......#
#.......#
#.!...o.#
#.......#
#########

######!*!*
#....#####
#........#
#q.*kkko.#
#........#
#....#####
######*!*!

#########
#.......#
#.......#
#...,...#
#.k.....#
#.....@.#
#.q.*.o.#
#.sssss.#
#.......#
#.......#
#.......#
#.......#
#########

p,.
!,k
o,.