Work in Progress https://twitter.com/NepalBitcoin

Toricoin.sol

pragma solidity ^0.4.19;
/**
    The MIT License (MIT)

    Copyright (c) 2015-2016 Oraclize SRL (https:/oraclize.it/)
    Copyright (c) 2016 Oraclize LTD  (https:/oraclize.it/)
    Copyright (c) 2016 Smart Contract Solutions, Inc. (https://openzeppelin.org/)
    Copyright (c) 2017 Potato Coin Foundation. (https://potatoin.foundation)
    Copyright (c) 2018 Nepal Blockchain R&D. (https://github.com/nepal-blockchain)

    Permission is hereby granted, free of charge, to any person obtaining
    a copy of this software and associated documentation files (the
    "Software"), to deal in the Software without restriction, including
    without limitation the rights to use, copy, modify, merge, publish,
    distribute, sublicense, and/or sell copies of the Software, and to
    permit persons to whom the Software is furnished to do so, subject to
    the following conditions:

    The above copyright notice and this permission notice shall be included
    in all copies or substantial portions of the Software.

    THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
    OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
    MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
    IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY
    CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
    TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
    SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
**/
library SafeMath {
    // https://github.com/OpenZeppelin/zeppelin-solidity/blob/master/contracts/math/SafeMath.sol 
    function mul(uint256 a, uint256 b) internal pure returns(uint256) {
        if (a == 0) {
            return 0;
        }
        uint256 c = a * b;
        assert(c / a == b);
        return c;
    }

    function div(uint256 a, uint256 b) internal pure returns(uint256) {
        // assert(b > 0); // Solidity automatically throws when dividing by 0
        uint256 c = a / b;
        // assert(a == b * c + a % b); // There is no case in which this doesn't hold
        return c;
    }

    function sub(uint256 a, uint256 b) internal pure returns(uint256) {
        assert(b <= a);
        return a - b;
    }

    function add(uint256 a, uint256 b) internal pure returns(uint256) {
        uint256 c = a + b;
        assert(c >= a);
        return c;
    }

    function decayRatio(
        uint256 _oldBal, uint256 _oldDecay, 
        uint256 _newBal, uint256 _newDecay
        ) internal pure returns(uint256 _finalDecay) 
        {
            /// final decay = (((new balance * old decay time ) + (old balance * new decay time)) / (new balance + old balance)) 
            uint256 decay = add(mul(_newBal, _oldDecay), mul(_oldBal, _newDecay));
            _finalDecay = div(decay, add(_newBal, _oldBal));
    }
}
contract OraclizeI {
    address public cbAddress;

    function query(uint _timestamp, string _datasource, string _arg) public payable returns(bytes32 _id);

    function getPrice(string _datasource) public returns(uint _dsprice);
}
contract OARI {
    function getAddress() public constant returns(address _addr);
}
contract UsingOraclize {
    /// minimal from https://github.com/oraclize/ethereum-api/blob/master/oraclizeAPI_0.4.sol

    using SafeMath for uint256;

    string public network = "rinkeby";

    OraclizeI public oraclize;
    OARI public OAR = OARI(0x51efaF4c8B3C9AfBD5aB9F4bbC82784Ab6ef8fAA);

    /// Oraclize Address Resolver (OAR)
    // Oraclize browser OAR >> 0x51efaF4c8B3C9AfBD5aB9F4bbC82784Ab6ef8fAA
    // Rinkeby testnet OAR >> 0x146500cfd35B22E4A392Fe0aDc06De1a1368Ed48
    // Ethereum mainnet >> 0x1d3B2638a7cC9f2CB3D298A3DA7a90B67E5506ed

    modifier oraclizeAPI {
        if (address(oraclize) != OAR.getAddress()) {
            oraclize = OraclizeI(OAR.getAddress());
        }
        _;
    }

    function dataPrice(string datasource) internal returns(uint256 price) {
        price = oraclize.getPrice(datasource);
    }

    function oraclizeQuery(string _datasource, string _arg, uint256 _value) oraclizeAPI internal returns(bytes32 id) {
        uint price = dataPrice(_datasource);
        assert(price <= _value);
        return oraclize.query.value(price)(0, _datasource, _arg);
    }

    function callbackAddress() oraclizeAPI internal returns(address) {
        return oraclize.cbAddress();
    }

    // parseInt
    function parseInt(string _a) internal pure returns(uint) {
        return parseInt(_a, 0);
    }

    // parseInt(parseFloat*10^_b)
    function parseInt(string _a, uint _b) internal pure returns(uint) {
        bytes memory bresult = bytes(_a);
        uint mint = 0;
        bool decimals = false;
        for (uint i = 0; i < bresult.length; i++) {
            if ((bresult[i] >= 48) && (bresult[i] <= 57)) {
                if (decimals) {
                    if (_b == 0)
                        break;
                    else
                        _b--;
                }
                mint *= 10;
                mint += uint(bresult[i]) - 48;
            } else if (bresult[i] == 46)
                decimals = true;
        }
        if (_b > 0)
            mint *= 10 ** _b;
        return mint;
    }

}
contract NepalTemperatureI {
    address public dev;
    struct TempDB {
        uint256 time;
        uint256 temp;
    }

    mapping(uint256 => TempDB) public temperature; // data[counter] = (time, temperature) 
    mapping(address => bool) public accessCheck; // write access check

    function updateTemperature() payable public returns(bool);

    function average7Calls() public view returns(uint256 _average);

}
contract UnderConstruction is NepalTemperatureI {

    function UnderConstruction() {
        dev = msg.sender;
    }

    function devWithdraw() public returns(bool) {
        require(msg.sender == dev && this.balance > 1e12);
        msg.sender.transfer(this.balance);
        return true;
    }

    function devKillSwitch() public {
        require(msg.sender == dev);
        selfdestruct(msg.sender);
    }


    function accessManager(address _newContract, bool _status) public {
        require(msg.sender == dev);
        accessCheck[_newContract] = _status;
    }

    function () public payable {
        revert();
    }
}
contract NepalTemperature is UnderConstruction, UsingOraclize {

    using SafeMath for uint256;

    uint256 public constant CALLGAP = 6 hours; // min gap between each call
    string public constant DATASOURCE = "WolframAlpha";
    string public constant QUERY = "Average temperature in Nepal";

    uint256 public nextCall; // time for next call
    uint256 public counter; // data counter
    bytes32 public callbackID; // callback Id from oraclize

    event TemperatureUpdate(uint256 _time, uint256 _temp);

    function NepalTemperature() oraclizeAPI {
        //init 7 days of data
        for (uint i = 0; i <= 7; i++) {
            temperature[i] = TempDB(now, uint256(9).add(i));
        }
        counter = 7;
        accessCheck[dev] = true;
    }

    function average7Calls() public view returns(uint256 _average) {
        uint256 end = counter.sub(1); ///gap between oraclize calls
        for (uint256 i = counter.sub(8); i < end; i++) {
            _average = _average.add(temperature[i].temp);
        }
        return _average.div(7);
    }

    function __callback(bytes32 ID, string result) public { //oraclize callback function
        require(msg.sender == callbackAddress() && ID == callbackID);
        uint256 _temp = uint256(parseInt(result));
        TempDB memory newData;
        newData.time = now;
        newData.temp = _temp;
        temperature[counter++] = newData;
        TemperatureUpdate(newData.time, newData.temp);
    }

    function updateTemperature() payable public returns(bool) {
        require(accessCheck[msg.sender] && nextCall < now && msg.value > 1e10);
        nextCall = now.add(CALLGAP);
        callbackID = oraclizeQuery(DATASOURCE, QUERY, msg.value);
        return true;
    }
}

contract ToricoinI {
    using SafeMath for uint256;

    NepalTemperatureI public NepalTemp; //temperature module

    //ERC20 basic
    string public constant name = "Smart Toricoin"; // #Toricoin
    string public constant symbol = "TORI"; // $TORI
    uint8 public constant decimals = 8; // 1 $TORI Coin = 100000000 saTori

    // TORI constants
    uint256 public constant FREETORI = 1e10; //free toricoins for new users
    uint256 public constant MAXDECAY = 3 years; // MAX decay limit    
    uint256 public constant MAXGROWTH = 50 days; // MAX growth limit
    uint256 public constant MINDECAY = 30 days; // MIN DECAY, starting point 
    uint256 public constant MINGROWTH = 7 days; // MIN cropcycle 
    uint256 public constant PLUSGROWTH = 7 days; // 7 days, increase 1 day per week in farm difficulty, up to MAX
    uint256 public constant PLUSDECAY = 14 days; // 30 days, increase final decay 1 day per month (30 days), only during harvest 
    uint256 public constant REWARDPERCENT = 20; // 100/20 = 5% for inspect / work
    
    uint256 public genesis; // Genesis timestamp
    uint256 public currentSupply;
    uint256 public totalWasted;
    uint256 public currentFarming;

    struct KISAN {
        uint256 balance;
        uint256 decayTime;
        uint256 wasted;
        uint256 harvestTime;
        uint256 farmTemp;
        uint32 farming;
    }

    mapping(address => KISAN) public farmer;

    event Transfer(address indexed _from, address indexed _to, uint256 _value);
    function totalSupply() public view returns(uint256);
    function transfer(address _to, uint256 _value) public returns(bool);
    function balanceOf(address _farm) public constant returns(uint256 balance);
    
    // TORICOIN function 
    function currentDecay() public constant returns(uint256 _decay);
    function currentGrowth() public constant returns(uint256 _growth);
    function currentReward(uint32 _farming, uint256 _initTemp) internal view returns(uint256 _reward);
    function inspect(address _owner) public;
    function work(address _owner) public;
    function harvest() public;
    function farm(uint32 _tori) public;
    function joinToriFoundation() public payable;
    function getLatestTemp() public payable;
}
contract Toricoin is ToricoinI {    
    function totalSupply() public view returns(uint256) {
        return currentSupply.add(currentFarming);
    }
    
    function currentDecay() public constant returns(uint256 _decay) {
        _decay = MINDECAY.add(((now.sub(genesis)).div(30 days)).mul(1 days));
        if (_decay > MAXDECAY) {
            _decay = MAXDECAY;
        }
    }

    function currentGrowth() public constant returns(uint256 _growth) {
        _growth = MINGROWTH.add(((now.sub(genesis)).div(PLUSGROWTH)).mul(1 days));
        if (_growth > MAXGROWTH) {
            _growth = MAXGROWTH;
        }
    }

    function currentReward(uint32 _farming, uint256 _initTemp) internal view returns(uint256 _reward) {
        uint256 currTemp = NepalTemp.average7Calls();
        uint256 multi; 
        if (_initTemp < currTemp) {
            multi = currTemp.sub(_initTemp).add(1);
            _reward = uint256(_farming).mul(multi);
        } else {
            multi = (_initTemp.sub(currTemp)).add(1);
            _reward = uint256(_farming).add(uint256(_farming).div(multi));
        }
        return _reward;
    }

    function transfer(address _to, uint256 _value) public returns(bool) {
        require(_to != address(0));
        address _from = msg.sender;
        KISAN storage _sender = farmer[_from];
        require(_sender.decayTime > now.add(1 hours));
        _sender.balance = (_sender.balance).sub(_value);
        KISAN storage _receiver = farmer[_to];
        _receiver.decayTime = decay(_receiver.balance, _receiver.decayTime, _value, _sender.decayTime);
        _receiver.balance = (_receiver.balance).add(_value);
        Transfer(_from, _to, _value);
        return true;
    }

    function Toricoin(address _npTemp) public {
        genesis = block.timestamp;
        NepalTemp = NepalTemperatureI(_npTemp);

    }

    function balanceOf(address _farmer) public constant returns(uint256 balance) {
        return (farmer[_farmer].balance).add(farmer[_farmer].farming);
    }

    function harvest() public {
        KISAN storage _farm = farmer[msg.sender];
        assert(_farm.farming > 0 && _farm.harvestTime < now);
        uint256 reward = currentReward(_farm.farming, _farm.farmTemp);
        _farm.decayTime = decay(_farm.balance, _farm.decayTime, reward, (_farm.harvestTime).add(currentDecay()));
        _farm.balance = (_farm.balance).add(reward);
        currentFarming = currentFarming.sub(_farm.farming);
        _farm.farming = uint32(0);
        currentSupply = currentSupply.add(reward);
        Transfer(address(0), msg.sender, reward);
    }

    function decay(uint256 _oldBalance, uint256 _oldTimer, uint256 _newBalance, uint256 _newTimer) internal view returns(uint256 _decayTime) {
        if (_oldBalance == 0 || _oldTimer < now) {
            _decayTime = _newTimer;
        } else {
            _decayTime = (_oldBalance).decayRatio(_oldTimer, _newBalance, _newTimer);
        }
    }

    function inspect(address _owner) public {
        require(msg.sender != _owner);
        KISAN storage _farm = farmer[_owner];
        assert(_farm.balance > 0 && _farm.decayTime < now);
        uint256 reward = (_farm.balance).div(REWARDPERCENT);
        if (reward < FREETORI) {
            reward = _farm.balance;
        }
        KISAN storage _inspector = farmer[msg.sender];
        _inspector.balance = (_inspector.balance).add(reward);
        _inspector.decayTime = decay(_inspector.balance, _inspector.decayTime, reward, now.add(15 days));
        currentSupply = currentSupply.sub((_farm.balance).sub(reward));
        _farm.wasted = _farm.wasted.add(_farm.balance);
        Transfer(_owner, address(0), _farm.balance);
        _farm.balance = uint256(0);
        Transfer(address(0), msg.sender, reward);
    }

    function work(address _owner) public {
        require(msg.sender != _owner);
        KISAN storage _farm = farmer[_owner];
        assert(_farm.farming > 0 && _farm.harvestTime < now.add(6 hours));
        KISAN storage _worker = farmer[msg.sender];
        uint256 reward = currentReward(_farm.farming, _farm.farmTemp);
        uint256 workerReward = reward.div(REWARDPERCENT);
        uint256 farmerReward = reward.sub(workerReward);
        uint256 nextDecay = (_farm.harvestTime).add(currentDecay());
        _worker.balance = (_worker.balance).add(workerReward);
        _worker.decayTime = decay(_worker.balance, _worker.decayTime, workerReward, nextDecay);
        _farm.farming = uint32(0);
        _farm.decayTime = decay(_farm.balance, _farm.decayTime, farmerReward, nextDecay);
        _farm.balance = (_farm.balance).add(farmerReward);        
        Transfer(address(0), msg.sender, workerReward);
        Transfer(address(0), _owner, farmerReward);
        currentSupply = currentSupply.add(reward);
        currentFarming = currentFarming.sub(_farm.farming);
    }

    function farm(uint32 _tori) public {
        KISAN storage _farm = farmer[msg.sender];
        assert(_tori > 0 && _farm.farming == 0);
        if (_farm.balance < _tori) {
            _tori = uint32(_farm.balance);
        }
        _farm.balance = (_farm.balance).sub(_tori);
        _farm.farming = _tori;
        _farm.farmTemp = NepalTemp.average7Calls();
        _farm.harvestTime = now.add(currentGrowth());
        Transfer(msg.sender, address(0), uint256(_tori));
        currentFarming = currentFarming.add(_tori);
        currentSupply = currentSupply.sub(_tori);
    }

    function joinToriFoundation() public payable {
        KISAN storage _farm = farmer[msg.sender];
        assert (msg.value > 9e17 && _farm.decayTime == 0);
        _farm.balance = FREETORI;
        _farm.decayTime = now.add(currentDecay());
        currentSupply = currentSupply.add(FREETORI);
        Transfer(address(0), msg.sender, FREETORI);
    }

    function getLatestTemp() public payable {
        assert (msg.value > 9e17 && NepalTemp.updateTemperature.value(msg.value)());
        KISAN storage _farm = farmer[msg.sender];
        uint256 reward = FREETORI.mul(10);
        _farm.balance = _farm.balance.add(reward);
        _farm.decayTime = decay(_farm.balance, _farm.decayTime, reward, now.add(currentDecay()));
        currentSupply = currentSupply.add(reward);
        Transfer(address(0), msg.sender, reward);
    }

    function toriExpireBOT(address[] _farms) public {
        assert (NepalTemp.accessCheck(msg.sender));
        for (uint i = 0; i < _farms.length; i++) {
            KISAN storage _farm = farmer[_farms[i]];
            assert(_farm.balance > 0 && now.sub(7 days) > _farm.decayTime);
            currentSupply = currentSupply.sub(_farm.balance);
            totalWasted = totalWasted.add(_farm.balance);
            _farm.wasted = (_farm.wasted).add(_farm.balance);
            _farm.balance = uint256(0);
            Transfer(_farms[i], address(0), _farm.balance);
        }
    }

    function toriFarmBOT(address[] _farms) public {
        assert (NepalTemp.accessCheck(msg.sender));
        for (uint i = 0; i < _farms.length; i++) {
            KISAN storage _farm = farmer[_farms[i]];
            assert(_farm.farming > 0 && now.sub(currentGrowth()) > _farm.harvestTime);
            currentFarming = currentFarming.sub(_farm.farming);
            _farm.wasted = (_farm.wasted).add(_farm.balance);
            _farm.wasted = _farm.farming;
            _farm.farming = uint32(0);
        }
    }

    modifier isDev() {
        require(msg.sender == NepalTemp.dev());
        _;
    }
    
    function changeTempModule(address _new) public isDev {
        NepalTemp = NepalTemperatureI(_new);
    }

    function devWithdraw() public isDev returns(bool) {
        (msg.sender).transfer((this.balance).div(2));
        return true;
    }

    function devKillSwitch() public isDev {
        selfdestruct(msg.sender);
    }
    
    function () public payable {
        revert();
    }
    
}