build.gradle

apply plugin: 'com.android.application'

android {
    compileSdkVersion 23
    buildToolsVersion "23.0.2"

    lintOptions {
        disable "MissingTranslation"
        disable "ExtraTranslation"
    }

    defaultConfig {
        applicationId "si.iskratel.sip.client"
        minSdkVersion 14
        targetSdkVersion 22
        versionCode 15
        versionName "2.0.3.0"
        buildConfigField("String", "USER_GUIDE_URL", "\"http://iskratel.com/en/Iskratel-Phone-x10-series#guide\"")
        buildConfigField("String", "FAQ_URL", "\"http://iskratel.com/en/Iskratel-Phone-x10-series#faq\"")
    }

    buildTypes {
        debug {
            resValue("string", "app_name", "IT-Phone Development")
            buildConfigField("String", "IDMS_URL", "\"https://idmsebc.iskratel.com/sa/dms/itphonem/provision\"")
            buildConfigField("String", "IDMS_ARMENIA_URL", "\"https://fmc.beeline.am/sa/dms/itphonem/provision\"")
            debuggable true
            applicationIdSuffix ".d"
            versionNameSuffix "-debug"
        }

        release {
            debuggable false
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }

    productFlavors {
        iskratel {
            resValue("string", "app_name", "IT-Phone A10")
            buildConfigField("String", "IDMS_URL", "\"https://idms.iskratel.si/dms/itphonem/provision\"")
        }

        iskratelVerification {
            resValue("string", "app_name", "IT-Phone Verification")
            buildConfigField("String", "IDMS_URL", "\"https://ibc12nginx.iskratel.mak/sa/dms/itphonem/provision\"")
        }

        // other brand flavors
        beelineArmenia {
            applicationId "si.iskratel.sip.client.beeline"
            resValue("string", "app_name", "Beeline Arm-A10")
            buildConfigField("String", "IDMS_URL", "\"https://fmc.beeline.am/sa/dms/itphonem/provision\"")
        }

        beelineKazakhstan {
            applicationId "si.iskratel.sip.client.beeline.kazakhstan"
            resValue("string", "app_name", "Beephone")
//            buildConfigField("String", "IDMS_URL", "\"https://fmc.beeline.am/sa/dms/itphonem/provision\"")
            buildConfigField("String", "IDMS_URL", "\"https://b2b.voip.2day.kz/sa/dms/itphonem/provision\"")
            buildConfigField("String", "USER_GUIDE_URL", "\"http://www.beeline.kz\"")
            buildConfigField("String", "FAQ_URL", "\"http://www.beeline.kz\"")
        }

        datagroup {
            applicationId "si.datagroup.sip.client"
            resValue("string", "app_name", "Dataphonе®")
//            buildConfigField("String", "IDMS_URL", "\"https://myvoip.datagroup.ua/sa/dms/itphonem/provision\"")
            buildConfigField("String", "IDMS_URL", "\"https://fmc.beeline.am/sa/dms/itphonem/provision\"")
            buildConfigField("String", "USER_GUIDE_URL", "\"http://www.datagroup.ua/assets/images/docs/UserGuide-Dataphone-a10.pdf\"")
            buildConfigField("String", "FAQ_URL", "\"http://www.datagroup.ua/assets/images/docs/FAQ-Dataphone-a10.pdf\"")
        }
    }

    packagingOptions {
        exclude 'META-INF/LICENSE.txt'
        exclude 'META-INF/LICENSE'
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_7
        targetCompatibility JavaVersion.VERSION_1_7
    }
}

dependencies {
    compile fileTree(include: ['*.jar'], dir: 'libs')
    //    testCompile 'junit:junit:4.12'
    compile 'com.android.support:appcompat-v7:23.1.1'
    compile('de.keyboardsurfer.android.widget:crouton:1.8.5@aar') {
        // exclusion is not necessary, but generally a good idea.
        exclude group: 'com.google.android', module: 'support-v4'
    }
    compile 'de.greenrobot:eventbus:2.4.0'
    compile project(':android-ngn-stack')
}