many_to_many_helper.ex

many_to_many_helper.ex

defmodule ManyToManyHelper do
  defmacro __using__(_opts) do
    quote do
      import Ecto.Query, only: [from: 2]
      import unquote(__MODULE__)
    end
  end

  defmacro many_to_many_params(opts) do
    association = Keyword.fetch!(opts, :association)
    repo = Keyword.fetch!(opts, :repo)
    module = Keyword.fetch!(opts, :module)

    quote do
      def unquote(:"put_#{association}")(
            %{params: %{unquote("#{association}_ids") => ""}} = changeset,
            _repo_opts
          ),
          do: Ecto.Changeset.put_assoc(changeset, unquote(association), [])

      def unquote(:"put_#{association}")(
            %{params: %{unquote("#{association}_ids") => ids}} = changeset,
            repo_opts
          ) do
        relations =
          from(r in unquote(module), where: r.id in ^ids)
          |> unquote(repo).all(repo_opts)

        Ecto.Changeset.put_assoc(changeset, unquote(association), relations)
      end

      def unquote(:"put_#{association}")(changeset, _repo_opts), do: changeset
    end
  end
end