Execution plan Computation Expressions

ExecutionPlan1.fsx

type Step =
    | Action of string
    | Branch of Step list list

type Plan =
    {
        Name : string
        Steps : Step list
    }

// The step and branch DSL members can be simple functions
let step name = Action name
let branch steps = Branch steps

type PlanBuilder () =

    member _.Yield _ =
        {
            Name = ""
            Steps = []
        }
    
    member _.Run state = state

    [<CustomOperation "name">]
    member _.Name (state, name) =
        { state with Name = name }

    [<CustomOperation "steps">]
    member _.Steps (state, steps) =
        { state with Steps = steps }

let plan = PlanBuilder ()

let x =
    plan {
        name "Chicken"
        steps [
            // The compiler reports errors for all the 
            // `step` and `branch` calls
            step "1"
            step "2"
            branch [
                [
                    step "3a"
                    step "4a"
                ]
                [
                    step "3b"
                    step "4b"
                ]
            ]
            step "5"
        ]
    }

ExecutionPlan2.fsx

type Step =
    | Action of string
    | Branch of Step list list

type Plan =
    {
        Name : string
        Steps : Step list
    }

// The step and branch DSL members can be builders of their own 
type ActionBuilder () =
    member _.Yield _ =
        Action ""
    [<CustomOperation "name">]
    member _.Name (_:Step, name) =
        Action name
let action = ActionBuilder ()

type BranchBuilder () =
    member _.Yield _ =
        Branch []
    [<CustomOperation "steps">]
    member _.Steps (_:Step, steps:Step list list ) =
        Branch steps
let branch = BranchBuilder ()

type PlanBuilder () =
    member _.Yield _ =
        {
            Name = ""
            Steps = []
        }
    [<CustomOperation "name">]
    member _.Name (state, name) : Plan =
        { state with Name = name }
    [<CustomOperation "steps">]
    member _.Steps (state, steps) : Plan =
        { state with Steps = steps }
let plan = PlanBuilder ()

let x =
    plan {
        name "Chicken"
        steps [
            action { name "1" }
            action { name "2" }
            branch {
                steps [
                    [
                        action { name "3a" }
                        action { name "4a" }
                    ]
                    [
                        action { name "3b" }
                        action { name "4b" }
                    ]
                ]
            }
            action { name "5" }
        ]
    }