Interesting use of 'finally' to slip some code in before a function returns

aop.as

package
{
	// end() is executed after the return statement but before the function returns!
	public function aop(method:Function, begin:Function, end:Function):Function
	{
		return function(...args):*
		{
			try
			{
				begin();
				return method.apply(null, args);
			}
			finally
			{
				end();
			}
		}
	}
}

AOPTest.as

// originally from Andy Shang http://bbs.9ria.com/viewthread.php?tid=47399

package
{
	import flash.display.Sprite;
		
	public class AOPTest extends Sprite
	{
		public function AOPTest()
		{
			trace(aop(sum, begin, end)(3, 5));
		}
		
		/*
		output:
		
		begin
		calculating...
		end
		8
		*/
		
	}
}

function sum(x:Number, y:Number):Number
{
	trace("calculating...")
	return x + y;
}

function begin():void
{
	trace("begin");
}

function end():void
{
	trace("end");
}

Removed distracting use of prototype; not relevant to the demonstration

A commenter on the 9ria thread had seen this pattern used in JavaScript to solve memory leaks.