Created
October 25, 2022 17:01
-
-
Save nola11/861c2e36d5073440c338a68f26d14b14 to your computer and use it in GitHub Desktop.
Created using remix-ide: Realtime Ethereum Contract Compiler and Runtime. Load this file by pasting this gists URL or ID at https://remix.ethereum.org/#version=soljson-v0.6.6+commit.6c089d02.js&optimize=true&runs=200&gist=
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
// SPDX-License-Identifier: MIT | |
// File: interfaces/IWETH.sol | |
pragma solidity >=0.5.0; | |
interface IWETH { | |
function deposit() external payable; | |
function transfer(address to, uint256 value) external returns (bool); | |
function withdraw(uint256) external; | |
} | |
// File: interfaces/IERC20.sol | |
pragma solidity >=0.5.0; | |
interface IERC20 { | |
event Approval(address indexed owner, address indexed spender, uint256 value); | |
event Transfer(address indexed from, address indexed to, uint256 value); | |
function name() external view returns (string memory); | |
function symbol() external view returns (string memory); | |
function decimals() external view returns (uint8); | |
function totalSupply() external view returns (uint256); | |
function balanceOf(address owner) external view returns (uint256); | |
function allowance(address owner, address spender) external view returns (uint256); | |
function approve(address spender, uint256 value) external returns (bool); | |
function transfer(address to, uint256 value) external returns (bool); | |
function transferFrom( | |
address from, | |
address to, | |
uint256 value | |
) external returns (bool); | |
} | |
// File: interfaces/IMindchainswapPair.sol | |
pragma solidity >=0.5.0; | |
interface IMindchainswapPair { | |
event Approval(address indexed owner, address indexed spender, uint256 value); | |
event Transfer(address indexed from, address indexed to, uint256 value); | |
function name() external pure returns (string memory); | |
function symbol() external pure returns (string memory); | |
function decimals() external pure returns (uint8); | |
function totalSupply() external view returns (uint256); | |
function balanceOf(address owner) external view returns (uint256); | |
function allowance(address owner, address spender) external view returns (uint256); | |
function approve(address spender, uint256 value) external returns (bool); | |
function transfer(address to, uint256 value) external returns (bool); | |
function transferFrom( | |
address from, | |
address to, | |
uint256 value | |
) external returns (bool); | |
function DOMAIN_SEPARATOR() external view returns (bytes32); | |
function PERMIT_TYPEHASH() external pure returns (bytes32); | |
function nonces(address owner) external view returns (uint256); | |
function permit( | |
address owner, | |
address spender, | |
uint256 value, | |
uint256 deadline, | |
uint8 v, | |
bytes32 r, | |
bytes32 s | |
) external; | |
event Mint(address indexed sender, uint256 amount0, uint256 amount1); | |
event Burn(address indexed sender, uint256 amount0, uint256 amount1, address indexed to); | |
event Swap( | |
address indexed sender, | |
uint256 amount0In, | |
uint256 amount1In, | |
uint256 amount0Out, | |
uint256 amount1Out, | |
address indexed to | |
); | |
event Sync(uint112 reserve0, uint112 reserve1); | |
function MINIMUM_LIQUIDITY() external pure returns (uint256); | |
function factory() external view returns (address); | |
function token0() external view returns (address); | |
function token1() external view returns (address); | |
function getReserves() | |
external | |
view | |
returns ( | |
uint112 reserve0, | |
uint112 reserve1, | |
uint32 blockTimestampLast | |
); | |
function price0CumulativeLast() external view returns (uint256); | |
function price1CumulativeLast() external view returns (uint256); | |
function kLast() external view returns (uint256); | |
function mint(address to) external returns (uint256 liquidity); | |
function burn(address to) external returns (uint256 amount0, uint256 amount1); | |
function swap( | |
uint256 amount0Out, | |
uint256 amount1Out, | |
address to, | |
bytes calldata data | |
) external; | |
function skim(address to) external; | |
function sync() external; | |
function initialize(address, address) external; | |
} | |
// File: libraries/SafeMath.sol | |
pragma solidity >=0.5.0 <0.7.0; | |
// a library for performing overflow-safe math, courtesy of DappHub (https://github.com/dapphub/ds-math) | |
library SafeMath { | |
function add(uint256 x, uint256 y) internal pure returns (uint256 z) { | |
require((z = x + y) >= x, "ds-math-add-overflow"); | |
} | |
function sub(uint256 x, uint256 y) internal pure returns (uint256 z) { | |
require((z = x - y) <= x, "ds-math-sub-underflow"); | |
} | |
function mul(uint256 x, uint256 y) internal pure returns (uint256 z) { | |
require(y == 0 || (z = x * y) / y == x, "ds-math-mul-overflow"); | |
} | |
} | |
// File: interfaces/IMindchainswapFactory.sol | |
pragma solidity >=0.5.0; | |
interface IMindchainswapFactory { | |
event PairCreated(address indexed token0, address indexed token1, address pair, uint256); | |
function feeTo() external view returns (address); | |
function feeToSetter() external view returns (address); | |
function getPair(address tokenA, address tokenB) external view returns (address pair); | |
function allPairs(uint256) external view returns (address pair); | |
function allPairsLength() external view returns (uint256); | |
function createPair(address tokenA, address tokenB) external returns (address pair); | |
function setFeeTo(address) external; | |
function setFeeToSetter(address) external; | |
function INIT_CODE_PAIR_HASH() external view returns (bytes32); | |
} | |
// File: libraries/MindchainswapLibrary.sol | |
pragma solidity >=0.5.0; | |
library MindchainswapLibrary { | |
using SafeMath for uint256; | |
// returns sorted token addresses, used to handle return values from pairs sorted in this order | |
function sortTokens(address tokenA, address tokenB) internal pure returns (address token0, address token1) { | |
require(tokenA != tokenB, "MindchainswapLibrary: IDENTICAL_ADDRESSES"); | |
(token0, token1) = tokenA < tokenB ? (tokenA, tokenB) : (tokenB, tokenA); | |
require(token0 != address(0), "MindchainswapLibrary: ZERO_ADDRESS"); | |
} | |
// calculates the CREATE2 address for a pair without making any external calls | |
function pairFor( | |
address factory, | |
address tokenA, | |
address tokenB | |
) internal pure returns (address pair) { | |
(address token0, address token1) = sortTokens(tokenA, tokenB); | |
pair = address( | |
uint256( | |
keccak256( | |
abi.encodePacked( | |
hex"ff", | |
factory, | |
keccak256(abi.encodePacked(token0, token1)), | |
hex"a5934690703a592a07e841ca29d5e5c79b5e22ed4749057bb216dc31100be1c0" // init code hash | |
) | |
) | |
) | |
); | |
} | |
// fetches and sorts the reserves for a pair | |
function getReserves( | |
address factory, | |
address tokenA, | |
address tokenB | |
) internal view returns (uint256 reserveA, uint256 reserveB) { | |
(address token0, ) = sortTokens(tokenA, tokenB); | |
pairFor(factory, tokenA, tokenB); | |
(uint256 reserve0, uint256 reserve1, ) = IMindchainswapPair(pairFor(factory, tokenA, tokenB)).getReserves(); | |
(reserveA, reserveB) = tokenA == token0 ? (reserve0, reserve1) : (reserve1, reserve0); | |
} | |
// given some amount of an asset and pair reserves, returns an equivalent amount of the other asset | |
function quote( | |
uint256 amountA, | |
uint256 reserveA, | |
uint256 reserveB | |
) internal pure returns (uint256 amountB) { | |
require(amountA > 0, "MindchainswapLibrary: INSUFFICIENT_AMOUNT"); | |
require(reserveA > 0 && reserveB > 0, "MindchainswapLibrary: INSUFFICIENT_LIQUIDITY"); | |
amountB = amountA.mul(reserveB) / reserveA; | |
} | |
// given an input amount of an asset and pair reserves, returns the maximum output amount of the other asset | |
function getAmountOut( | |
uint256 amountIn, | |
uint256 reserveIn, | |
uint256 reserveOut | |
) internal pure returns (uint256 amountOut) { | |
require(amountIn > 0, "MindchainswapLibrary: INSUFFICIENT_INPUT_AMOUNT"); | |
require(reserveIn > 0 && reserveOut > 0, "MindchainswapLibrary: INSUFFICIENT_LIQUIDITY"); | |
uint256 amountInWithFee = amountIn.mul(9975); | |
uint256 numerator = amountInWithFee.mul(reserveOut); | |
uint256 denominator = reserveIn.mul(10000).add(amountInWithFee); | |
amountOut = numerator / denominator; | |
} | |
// given an output amount of an asset and pair reserves, returns a required input amount of the other asset | |
function getAmountIn( | |
uint256 amountOut, | |
uint256 reserveIn, | |
uint256 reserveOut | |
) internal pure returns (uint256 amountIn) { | |
require(amountOut > 0, "MindchainswapLibrary: INSUFFICIENT_OUTPUT_AMOUNT"); | |
require(reserveIn > 0 && reserveOut > 0, "MindchainswapLibrary: INSUFFICIENT_LIQUIDITY"); | |
uint256 numerator = reserveIn.mul(amountOut).mul(10000); | |
uint256 denominator = reserveOut.sub(amountOut).mul(9975); | |
amountIn = (numerator / denominator).add(1); | |
} | |
// performs chained getAmountOut calculations on any number of pairs | |
function getAmountsOut( | |
address factory, | |
uint256 amountIn, | |
address[] memory path | |
) internal view returns (uint256[] memory amounts) { | |
require(path.length >= 2, "MindchainswapLibrary: INVALID_PATH"); | |
amounts = new uint256[](path.length); | |
amounts[0] = amountIn; | |
for (uint256 i; i < path.length - 1; i++) { | |
(uint256 reserveIn, uint256 reserveOut) = getReserves(factory, path[i], path[i + 1]); | |
amounts[i + 1] = getAmountOut(amounts[i], reserveIn, reserveOut); | |
} | |
} | |
// performs chained getAmountIn calculations on any number of pairs | |
function getAmountsIn( | |
address factory, | |
uint256 amountOut, | |
address[] memory path | |
) internal view returns (uint256[] memory amounts) { | |
require(path.length >= 2, "MindchainswapLibrary: INVALID_PATH"); | |
amounts = new uint256[](path.length); | |
amounts[amounts.length - 1] = amountOut; | |
for (uint256 i = path.length - 1; i > 0; i--) { | |
(uint256 reserveIn, uint256 reserveOut) = getReserves(factory, path[i - 1], path[i]); | |
amounts[i - 1] = getAmountIn(amounts[i], reserveIn, reserveOut); | |
} | |
} | |
} | |
// File: interfaces/IMindchainswapRouter01.sol | |
pragma solidity >=0.6.2; | |
interface IMindchainswapRouter01 { | |
function factory() external pure returns (address); | |
function WETH() external pure returns (address); | |
function addLiquidity( | |
address tokenA, | |
address tokenB, | |
uint256 amountADesired, | |
uint256 amountBDesired, | |
uint256 amountAMin, | |
uint256 amountBMin, | |
address to, | |
uint256 deadline | |
) | |
external | |
returns ( | |
uint256 amountA, | |
uint256 amountB, | |
uint256 liquidity | |
); | |
function addLiquidityETH( | |
address token, | |
uint256 amountTokenDesired, | |
uint256 amountTokenMin, | |
uint256 amountETHMin, | |
address to, | |
uint256 deadline | |
) | |
external | |
payable | |
returns ( | |
uint256 amountToken, | |
uint256 amountETH, | |
uint256 liquidity | |
); | |
function removeLiquidity( | |
address tokenA, | |
address tokenB, | |
uint256 liquidity, | |
uint256 amountAMin, | |
uint256 amountBMin, | |
address to, | |
uint256 deadline | |
) external returns (uint256 amountA, uint256 amountB); | |
function removeLiquidityETH( | |
address token, | |
uint256 liquidity, | |
uint256 amountTokenMin, | |
uint256 amountETHMin, | |
address to, | |
uint256 deadline | |
) external returns (uint256 amountToken, uint256 amountETH); | |
function removeLiquidityWithPermit( | |
address tokenA, | |
address tokenB, | |
uint256 liquidity, | |
uint256 amountAMin, | |
uint256 amountBMin, | |
address to, | |
uint256 deadline, | |
bool approveMax, | |
uint8 v, | |
bytes32 r, | |
bytes32 s | |
) external returns (uint256 amountA, uint256 amountB); | |
function removeLiquidityETHWithPermit( | |
address token, | |
uint256 liquidity, | |
uint256 amountTokenMin, | |
uint256 amountETHMin, | |
address to, | |
uint256 deadline, | |
bool approveMax, | |
uint8 v, | |
bytes32 r, | |
bytes32 s | |
) external returns (uint256 amountToken, uint256 amountETH); | |
function swapExactTokensForTokens( | |
uint256 amountIn, | |
uint256 amountOutMin, | |
address[] calldata path, | |
address to, | |
uint256 deadline | |
) external returns (uint256[] memory amounts); | |
function swapTokensForExactTokens( | |
uint256 amountOut, | |
uint256 amountInMax, | |
address[] calldata path, | |
address to, | |
uint256 deadline | |
) external returns (uint256[] memory amounts); | |
function swapExactETHForTokens( | |
uint256 amountOutMin, | |
address[] calldata path, | |
address to, | |
uint256 deadline | |
) external payable returns (uint256[] memory amounts); | |
function swapTokensForExactETH( | |
uint256 amountOut, | |
uint256 amountInMax, | |
address[] calldata path, | |
address to, | |
uint256 deadline | |
) external returns (uint256[] memory amounts); | |
function swapExactTokensForETH( | |
uint256 amountIn, | |
uint256 amountOutMin, | |
address[] calldata path, | |
address to, | |
uint256 deadline | |
) external returns (uint256[] memory amounts); | |
function swapETHForExactTokens( | |
uint256 amountOut, | |
address[] calldata path, | |
address to, | |
uint256 deadline | |
) external payable returns (uint256[] memory amounts); | |
function quote( | |
uint256 amountA, | |
uint256 reserveA, | |
uint256 reserveB | |
) external pure returns (uint256 amountB); | |
function getAmountOut( | |
uint256 amountIn, | |
uint256 reserveIn, | |
uint256 reserveOut | |
) external pure returns (uint256 amountOut); | |
function getAmountIn( | |
uint256 amountOut, | |
uint256 reserveIn, | |
uint256 reserveOut | |
) external pure returns (uint256 amountIn); | |
function getAmountsOut(uint256 amountIn, address[] calldata path) external view returns (uint256[] memory amounts); | |
function getAmountsIn(uint256 amountOut, address[] calldata path) external view returns (uint256[] memory amounts); | |
} | |
// File: interfaces/IMindchainswapRouter02.sol | |
pragma solidity >=0.6.2; | |
interface IMindchainswapRouter02 is IMindchainswapRouter01 { | |
function removeLiquidityETHSupportingFeeOnTransferTokens( | |
address token, | |
uint256 liquidity, | |
uint256 amountTokenMin, | |
uint256 amountETHMin, | |
address to, | |
uint256 deadline | |
) external returns (uint256 amountETH); | |
function removeLiquidityETHWithPermitSupportingFeeOnTransferTokens( | |
address token, | |
uint256 liquidity, | |
uint256 amountTokenMin, | |
uint256 amountETHMin, | |
address to, | |
uint256 deadline, | |
bool approveMax, | |
uint8 v, | |
bytes32 r, | |
bytes32 s | |
) external returns (uint256 amountETH); | |
function swapExactTokensForTokensSupportingFeeOnTransferTokens( | |
uint256 amountIn, | |
uint256 amountOutMin, | |
address[] calldata path, | |
address to, | |
uint256 deadline | |
) external; | |
function swapExactETHForTokensSupportingFeeOnTransferTokens( | |
uint256 amountOutMin, | |
address[] calldata path, | |
address to, | |
uint256 deadline | |
) external payable; | |
function swapExactTokensForETHSupportingFeeOnTransferTokens( | |
uint256 amountIn, | |
uint256 amountOutMin, | |
address[] calldata path, | |
address to, | |
uint256 deadline | |
) external; | |
} | |
// File: @uniswap/lib/contracts/libraries/TransferHelper.sol | |
pragma solidity >=0.6.0; | |
// helper methods for interacting with ERC20 tokens and sending ETH that do not consistently return true/false | |
library TransferHelper { | |
function safeApprove( | |
address token, | |
address to, | |
uint256 value | |
) internal { | |
// bytes4(keccak256(bytes('approve(address,uint256)'))); | |
(bool success, bytes memory data) = token.call(abi.encodeWithSelector(0x095ea7b3, to, value)); | |
require( | |
success && (data.length == 0 || abi.decode(data, (bool))), | |
'TransferHelper::safeApprove: approve failed' | |
); | |
} | |
function safeTransfer( | |
address token, | |
address to, | |
uint256 value | |
) internal { | |
// bytes4(keccak256(bytes('transfer(address,uint256)'))); | |
(bool success, bytes memory data) = token.call(abi.encodeWithSelector(0xa9059cbb, to, value)); | |
require( | |
success && (data.length == 0 || abi.decode(data, (bool))), | |
'TransferHelper::safeTransfer: transfer failed' | |
); | |
} | |
function safeTransferFrom( | |
address token, | |
address from, | |
address to, | |
uint256 value | |
) internal { | |
// bytes4(keccak256(bytes('transferFrom(address,address,uint256)'))); | |
(bool success, bytes memory data) = token.call(abi.encodeWithSelector(0x23b872dd, from, to, value)); | |
require( | |
success && (data.length == 0 || abi.decode(data, (bool))), | |
'TransferHelper::transferFrom: transferFrom failed' | |
); | |
} | |
function safeTransferETH(address to, uint256 value) internal { | |
(bool success, ) = to.call{value: value}(new bytes(0)); | |
require(success, 'TransferHelper::safeTransferETH: ETH transfer failed'); | |
} | |
} | |
// File: MindchainswapRouter.sol | |
pragma solidity =0.6.6; | |
contract MindchainswapRouter is IMindchainswapRouter02 { | |
using SafeMath for uint256; | |
address public immutable override factory; | |
address public immutable override WETH; | |
modifier ensure(uint256 deadline) { | |
require(deadline >= block.timestamp, "MindchainswapRouter: EXPIRED"); | |
_; | |
} | |
constructor(address _factory, address _WETH) public { | |
factory = _factory; | |
WETH = _WETH; | |
} | |
receive() external payable { | |
assert(msg.sender == WETH); // only accept ETH via fallback from the WETH contract | |
} | |
// **** ADD LIQUIDITY **** | |
function _addLiquidity( | |
address tokenA, | |
address tokenB, | |
uint256 amountADesired, | |
uint256 amountBDesired, | |
uint256 amountAMin, | |
uint256 amountBMin | |
) internal virtual returns (uint256 amountA, uint256 amountB) { | |
// create the pair if it doesn't exist yet | |
if (IMindchainswapFactory(factory).getPair(tokenA, tokenB) == address(0)) { | |
IMindchainswapFactory(factory).createPair(tokenA, tokenB); | |
} | |
(uint256 reserveA, uint256 reserveB) = MindchainswapLibrary.getReserves(factory, tokenA, tokenB); | |
if (reserveA == 0 && reserveB == 0) { | |
(amountA, amountB) = (amountADesired, amountBDesired); | |
} else { | |
uint256 amountBOptimal = MindchainswapLibrary.quote(amountADesired, reserveA, reserveB); | |
if (amountBOptimal <= amountBDesired) { | |
require(amountBOptimal >= amountBMin, "MindchainswapRouter: INSUFFICIENT_B_AMOUNT"); | |
(amountA, amountB) = (amountADesired, amountBOptimal); | |
} else { | |
uint256 amountAOptimal = MindchainswapLibrary.quote(amountBDesired, reserveB, reserveA); | |
assert(amountAOptimal <= amountADesired); | |
require(amountAOptimal >= amountAMin, "MindchainswapRouter: INSUFFICIENT_A_AMOUNT"); | |
(amountA, amountB) = (amountAOptimal, amountBDesired); | |
} | |
} | |
} | |
function addLiquidity( | |
address tokenA, | |
address tokenB, | |
uint256 amountADesired, | |
uint256 amountBDesired, | |
uint256 amountAMin, | |
uint256 amountBMin, | |
address to, | |
uint256 deadline | |
) | |
external | |
virtual | |
override | |
ensure(deadline) | |
returns ( | |
uint256 amountA, | |
uint256 amountB, | |
uint256 liquidity | |
) | |
{ | |
(amountA, amountB) = _addLiquidity(tokenA, tokenB, amountADesired, amountBDesired, amountAMin, amountBMin); | |
address pair = MindchainswapLibrary.pairFor(factory, tokenA, tokenB); | |
TransferHelper.safeTransferFrom(tokenA, msg.sender, pair, amountA); | |
TransferHelper.safeTransferFrom(tokenB, msg.sender, pair, amountB); | |
liquidity = IMindchainswapPair(pair).mint(to); | |
} | |
function addLiquidityETH( | |
address token, | |
uint256 amountTokenDesired, | |
uint256 amountTokenMin, | |
uint256 amountETHMin, | |
address to, | |
uint256 deadline | |
) | |
external | |
payable | |
virtual | |
override | |
ensure(deadline) | |
returns ( | |
uint256 amountToken, | |
uint256 amountETH, | |
uint256 liquidity | |
) | |
{ | |
(amountToken, amountETH) = _addLiquidity( | |
token, | |
WETH, | |
amountTokenDesired, | |
msg.value, | |
amountTokenMin, | |
amountETHMin | |
); | |
address pair = MindchainswapLibrary.pairFor(factory, token, WETH); | |
TransferHelper.safeTransferFrom(token, msg.sender, pair, amountToken); | |
IWETH(WETH).deposit{value: amountETH}(); | |
assert(IWETH(WETH).transfer(pair, amountETH)); | |
liquidity = IMindchainswapPair(pair).mint(to); | |
// refund dust eth, if any | |
if (msg.value > amountETH) TransferHelper.safeTransferETH(msg.sender, msg.value - amountETH); | |
} | |
// **** REMOVE LIQUIDITY **** | |
function removeLiquidity( | |
address tokenA, | |
address tokenB, | |
uint256 liquidity, | |
uint256 amountAMin, | |
uint256 amountBMin, | |
address to, | |
uint256 deadline | |
) public virtual override ensure(deadline) returns (uint256 amountA, uint256 amountB) { | |
address pair = MindchainswapLibrary.pairFor(factory, tokenA, tokenB); | |
IMindchainswapPair(pair).transferFrom(msg.sender, pair, liquidity); // send liquidity to pair | |
(uint256 amount0, uint256 amount1) = IMindchainswapPair(pair).burn(to); | |
(address token0, ) = MindchainswapLibrary.sortTokens(tokenA, tokenB); | |
(amountA, amountB) = tokenA == token0 ? (amount0, amount1) : (amount1, amount0); | |
require(amountA >= amountAMin, "MindchainswapRouter: INSUFFICIENT_A_AMOUNT"); | |
require(amountB >= amountBMin, "MindchainswapRouter: INSUFFICIENT_B_AMOUNT"); | |
} | |
function removeLiquidityETH( | |
address token, | |
uint256 liquidity, | |
uint256 amountTokenMin, | |
uint256 amountETHMin, | |
address to, | |
uint256 deadline | |
) public virtual override ensure(deadline) returns (uint256 amountToken, uint256 amountETH) { | |
(amountToken, amountETH) = removeLiquidity( | |
token, | |
WETH, | |
liquidity, | |
amountTokenMin, | |
amountETHMin, | |
address(this), | |
deadline | |
); | |
TransferHelper.safeTransfer(token, to, amountToken); | |
IWETH(WETH).withdraw(amountETH); | |
TransferHelper.safeTransferETH(to, amountETH); | |
} | |
function removeLiquidityWithPermit( | |
address tokenA, | |
address tokenB, | |
uint256 liquidity, | |
uint256 amountAMin, | |
uint256 amountBMin, | |
address to, | |
uint256 deadline, | |
bool approveMax, | |
uint8 v, | |
bytes32 r, | |
bytes32 s | |
) external virtual override returns (uint256 amountA, uint256 amountB) { | |
address pair = MindchainswapLibrary.pairFor(factory, tokenA, tokenB); | |
uint256 value = approveMax ? uint256(-1) : liquidity; | |
IMindchainswapPair(pair).permit(msg.sender, address(this), value, deadline, v, r, s); | |
(amountA, amountB) = removeLiquidity(tokenA, tokenB, liquidity, amountAMin, amountBMin, to, deadline); | |
} | |
function removeLiquidityETHWithPermit( | |
address token, | |
uint256 liquidity, | |
uint256 amountTokenMin, | |
uint256 amountETHMin, | |
address to, | |
uint256 deadline, | |
bool approveMax, | |
uint8 v, | |
bytes32 r, | |
bytes32 s | |
) external virtual override returns (uint256 amountToken, uint256 amountETH) { | |
address pair = MindchainswapLibrary.pairFor(factory, token, WETH); | |
uint256 value = approveMax ? uint256(-1) : liquidity; | |
IMindchainswapPair(pair).permit(msg.sender, address(this), value, deadline, v, r, s); | |
(amountToken, amountETH) = removeLiquidityETH(token, liquidity, amountTokenMin, amountETHMin, to, deadline); | |
} | |
// **** REMOVE LIQUIDITY (supporting fee-on-transfer tokens) **** | |
function removeLiquidityETHSupportingFeeOnTransferTokens( | |
address token, | |
uint256 liquidity, | |
uint256 amountTokenMin, | |
uint256 amountETHMin, | |
address to, | |
uint256 deadline | |
) public virtual override ensure(deadline) returns (uint256 amountETH) { | |
(, amountETH) = removeLiquidity(token, WETH, liquidity, amountTokenMin, amountETHMin, address(this), deadline); | |
TransferHelper.safeTransfer(token, to, IERC20(token).balanceOf(address(this))); | |
IWETH(WETH).withdraw(amountETH); | |
TransferHelper.safeTransferETH(to, amountETH); | |
} | |
function removeLiquidityETHWithPermitSupportingFeeOnTransferTokens( | |
address token, | |
uint256 liquidity, | |
uint256 amountTokenMin, | |
uint256 amountETHMin, | |
address to, | |
uint256 deadline, | |
bool approveMax, | |
uint8 v, | |
bytes32 r, | |
bytes32 s | |
) external virtual override returns (uint256 amountETH) { | |
address pair = MindchainswapLibrary.pairFor(factory, token, WETH); | |
uint256 value = approveMax ? uint256(-1) : liquidity; | |
IMindchainswapPair(pair).permit(msg.sender, address(this), value, deadline, v, r, s); | |
amountETH = removeLiquidityETHSupportingFeeOnTransferTokens( | |
token, | |
liquidity, | |
amountTokenMin, | |
amountETHMin, | |
to, | |
deadline | |
); | |
} | |
// **** SWAP **** | |
// requires the initial amount to have already been sent to the first pair | |
function _swap( | |
uint256[] memory amounts, | |
address[] memory path, | |
address _to | |
) internal virtual { | |
for (uint256 i; i < path.length - 1; i++) { | |
(address input, address output) = (path[i], path[i + 1]); | |
(address token0, ) = MindchainswapLibrary.sortTokens(input, output); | |
uint256 amountOut = amounts[i + 1]; | |
(uint256 amount0Out, uint256 amount1Out) = | |
input == token0 ? (uint256(0), amountOut) : (amountOut, uint256(0)); | |
address to = i < path.length - 2 ? MindchainswapLibrary.pairFor(factory, output, path[i + 2]) : _to; | |
IMindchainswapPair(MindchainswapLibrary.pairFor(factory, input, output)).swap(amount0Out, amount1Out, to, new bytes(0)); | |
} | |
} | |
function swapExactTokensForTokens( | |
uint256 amountIn, | |
uint256 amountOutMin, | |
address[] calldata path, | |
address to, | |
uint256 deadline | |
) external virtual override ensure(deadline) returns (uint256[] memory amounts) { | |
amounts = MindchainswapLibrary.getAmountsOut(factory, amountIn, path); | |
require(amounts[amounts.length - 1] >= amountOutMin, "MindchainswapRouter: INSUFFICIENT_OUTPUT_AMOUNT"); | |
TransferHelper.safeTransferFrom( | |
path[0], | |
msg.sender, | |
MindchainswapLibrary.pairFor(factory, path[0], path[1]), | |
amounts[0] | |
); | |
_swap(amounts, path, to); | |
} | |
function swapTokensForExactTokens( | |
uint256 amountOut, | |
uint256 amountInMax, | |
address[] calldata path, | |
address to, | |
uint256 deadline | |
) external virtual override ensure(deadline) returns (uint256[] memory amounts) { | |
amounts = MindchainswapLibrary.getAmountsIn(factory, amountOut, path); | |
require(amounts[0] <= amountInMax, "MindchainswapRouter: EXCESSIVE_INPUT_AMOUNT"); | |
TransferHelper.safeTransferFrom( | |
path[0], | |
msg.sender, | |
MindchainswapLibrary.pairFor(factory, path[0], path[1]), | |
amounts[0] | |
); | |
_swap(amounts, path, to); | |
} | |
function swapExactETHForTokens( | |
uint256 amountOutMin, | |
address[] calldata path, | |
address to, | |
uint256 deadline | |
) external payable virtual override ensure(deadline) returns (uint256[] memory amounts) { | |
require(path[0] == WETH, "MindchainswapRouter: INVALID_PATH"); | |
amounts = MindchainswapLibrary.getAmountsOut(factory, msg.value, path); | |
require(amounts[amounts.length - 1] >= amountOutMin, "MindchainswapRouter: INSUFFICIENT_OUTPUT_AMOUNT"); | |
IWETH(WETH).deposit{value: amounts[0]}(); | |
assert(IWETH(WETH).transfer(MindchainswapLibrary.pairFor(factory, path[0], path[1]), amounts[0])); | |
_swap(amounts, path, to); | |
} | |
function swapTokensForExactETH( | |
uint256 amountOut, | |
uint256 amountInMax, | |
address[] calldata path, | |
address to, | |
uint256 deadline | |
) external virtual override ensure(deadline) returns (uint256[] memory amounts) { | |
require(path[path.length - 1] == WETH, "MindchainswapRouter: INVALID_PATH"); | |
amounts = MindchainswapLibrary.getAmountsIn(factory, amountOut, path); | |
require(amounts[0] <= amountInMax, "MindchainswapRouter: EXCESSIVE_INPUT_AMOUNT"); | |
TransferHelper.safeTransferFrom( | |
path[0], | |
msg.sender, | |
MindchainswapLibrary.pairFor(factory, path[0], path[1]), | |
amounts[0] | |
); | |
_swap(amounts, path, address(this)); | |
IWETH(WETH).withdraw(amounts[amounts.length - 1]); | |
TransferHelper.safeTransferETH(to, amounts[amounts.length - 1]); | |
} | |
function swapExactTokensForETH( | |
uint256 amountIn, | |
uint256 amountOutMin, | |
address[] calldata path, | |
address to, | |
uint256 deadline | |
) external virtual override ensure(deadline) returns (uint256[] memory amounts) { | |
require(path[path.length - 1] == WETH, "MindchainswapRouter: INVALID_PATH"); | |
amounts = MindchainswapLibrary.getAmountsOut(factory, amountIn, path); | |
require(amounts[amounts.length - 1] >= amountOutMin, "MindchainswapRouter: INSUFFICIENT_OUTPUT_AMOUNT"); | |
TransferHelper.safeTransferFrom( | |
path[0], | |
msg.sender, | |
MindchainswapLibrary.pairFor(factory, path[0], path[1]), | |
amounts[0] | |
); | |
_swap(amounts, path, address(this)); | |
IWETH(WETH).withdraw(amounts[amounts.length - 1]); | |
TransferHelper.safeTransferETH(to, amounts[amounts.length - 1]); | |
} | |
function swapETHForExactTokens( | |
uint256 amountOut, | |
address[] calldata path, | |
address to, | |
uint256 deadline | |
) external payable virtual override ensure(deadline) returns (uint256[] memory amounts) { | |
require(path[0] == WETH, "MindchainswapRouter: INVALID_PATH"); | |
amounts = MindchainswapLibrary.getAmountsIn(factory, amountOut, path); | |
require(amounts[0] <= msg.value, "MindchainswapRouter: EXCESSIVE_INPUT_AMOUNT"); | |
IWETH(WETH).deposit{value: amounts[0]}(); | |
assert(IWETH(WETH).transfer(MindchainswapLibrary.pairFor(factory, path[0], path[1]), amounts[0])); | |
_swap(amounts, path, to); | |
// refund dust eth, if any | |
if (msg.value > amounts[0]) TransferHelper.safeTransferETH(msg.sender, msg.value - amounts[0]); | |
} | |
// **** SWAP (supporting fee-on-transfer tokens) **** | |
// requires the initial amount to have already been sent to the first pair | |
function _swapSupportingFeeOnTransferTokens(address[] memory path, address _to) internal virtual { | |
for (uint256 i; i < path.length - 1; i++) { | |
(address input, address output) = (path[i], path[i + 1]); | |
(address token0, ) = MindchainswapLibrary.sortTokens(input, output); | |
IMindchainswapPair pair = IMindchainswapPair(MindchainswapLibrary.pairFor(factory, input, output)); | |
uint256 amountInput; | |
uint256 amountOutput; | |
{ | |
// scope to avoid stack too deep errors | |
(uint256 reserve0, uint256 reserve1, ) = pair.getReserves(); | |
(uint256 reserveInput, uint256 reserveOutput) = | |
input == token0 ? (reserve0, reserve1) : (reserve1, reserve0); | |
amountInput = IERC20(input).balanceOf(address(pair)).sub(reserveInput); | |
amountOutput = MindchainswapLibrary.getAmountOut(amountInput, reserveInput, reserveOutput); | |
} | |
(uint256 amount0Out, uint256 amount1Out) = | |
input == token0 ? (uint256(0), amountOutput) : (amountOutput, uint256(0)); | |
address to = i < path.length - 2 ? MindchainswapLibrary.pairFor(factory, output, path[i + 2]) : _to; | |
pair.swap(amount0Out, amount1Out, to, new bytes(0)); | |
} | |
} | |
function swapExactTokensForTokensSupportingFeeOnTransferTokens( | |
uint256 amountIn, | |
uint256 amountOutMin, | |
address[] calldata path, | |
address to, | |
uint256 deadline | |
) external virtual override ensure(deadline) { | |
TransferHelper.safeTransferFrom( | |
path[0], | |
msg.sender, | |
MindchainswapLibrary.pairFor(factory, path[0], path[1]), | |
amountIn | |
); | |
uint256 balanceBefore = IERC20(path[path.length - 1]).balanceOf(to); | |
_swapSupportingFeeOnTransferTokens(path, to); | |
require( | |
IERC20(path[path.length - 1]).balanceOf(to).sub(balanceBefore) >= amountOutMin, | |
"MindchainswapRouter: INSUFFICIENT_OUTPUT_AMOUNT" | |
); | |
} | |
function swapExactETHForTokensSupportingFeeOnTransferTokens( | |
uint256 amountOutMin, | |
address[] calldata path, | |
address to, | |
uint256 deadline | |
) external payable virtual override ensure(deadline) { | |
require(path[0] == WETH, "MindchainswapRouter: INVALID_PATH"); | |
uint256 amountIn = msg.value; | |
IWETH(WETH).deposit{value: amountIn}(); | |
assert(IWETH(WETH).transfer(MindchainswapLibrary.pairFor(factory, path[0], path[1]), amountIn)); | |
uint256 balanceBefore = IERC20(path[path.length - 1]).balanceOf(to); | |
_swapSupportingFeeOnTransferTokens(path, to); | |
require( | |
IERC20(path[path.length - 1]).balanceOf(to).sub(balanceBefore) >= amountOutMin, | |
"MindchainswapRouter: INSUFFICIENT_OUTPUT_AMOUNT" | |
); | |
} | |
function swapExactTokensForETHSupportingFeeOnTransferTokens( | |
uint256 amountIn, | |
uint256 amountOutMin, | |
address[] calldata path, | |
address to, | |
uint256 deadline | |
) external virtual override ensure(deadline) { | |
require(path[path.length - 1] == WETH, "MindchainswapRouter: INVALID_PATH"); | |
TransferHelper.safeTransferFrom( | |
path[0], | |
msg.sender, | |
MindchainswapLibrary.pairFor(factory, path[0], path[1]), | |
amountIn | |
); | |
_swapSupportingFeeOnTransferTokens(path, address(this)); | |
uint256 amountOut = IERC20(WETH).balanceOf(address(this)); | |
require(amountOut >= amountOutMin, "MindchainswapRouter: INSUFFICIENT_OUTPUT_AMOUNT"); | |
IWETH(WETH).withdraw(amountOut); | |
TransferHelper.safeTransferETH(to, amountOut); | |
} | |
// **** LIBRARY FUNCTIONS **** | |
function quote( | |
uint256 amountA, | |
uint256 reserveA, | |
uint256 reserveB | |
) public pure virtual override returns (uint256 amountB) { | |
return MindchainswapLibrary.quote(amountA, reserveA, reserveB); | |
} | |
function getAmountOut( | |
uint256 amountIn, | |
uint256 reserveIn, | |
uint256 reserveOut | |
) public pure virtual override returns (uint256 amountOut) { | |
return MindchainswapLibrary.getAmountOut(amountIn, reserveIn, reserveOut); | |
} | |
function getAmountIn( | |
uint256 amountOut, | |
uint256 reserveIn, | |
uint256 reserveOut | |
) public pure virtual override returns (uint256 amountIn) { | |
return MindchainswapLibrary.getAmountIn(amountOut, reserveIn, reserveOut); | |
} | |
function getAmountsOut(uint256 amountIn, address[] memory path) | |
public | |
view | |
virtual | |
override | |
returns (uint256[] memory amounts) | |
{ | |
return MindchainswapLibrary.getAmountsOut(factory, amountIn, path); | |
} | |
function getAmountsIn(uint256 amountOut, address[] memory path) | |
public | |
view | |
virtual | |
override | |
returns (uint256[] memory amounts) | |
{ | |
return MindchainswapLibrary.getAmountsIn(factory, amountOut, path); | |
} | |
} |
Sign up for free
to join this conversation on GitHub.
Already have an account?
Sign in to comment