derive_specs.clj

(require '[spec-provider.provider :as sp])

(defn derive-specs [var & args]
  (let [ns-sym (ns-name (:ns (meta var)))
        ns-name (name ns-sym)
        derived-specs (atom [])
        fn-var-info (into [] (keep (fn [[var-sym var]]
                                     (let [x (deref var)]
                                       (when (fn? x)
                                         [var var-sym x]))))
                          (ns-interns ns-sym))
        new-defs (into [] (map
                           (fn [[var var-sym f]]
                             (let [ret-key (keyword (str ns-name "." var-sym) "ret")]
                               [var (fn [& args]
                                      (let [ret (apply f args)]
                                        (swap! derived-specs
                                               conj {:name var-sym
                                                     :ret (sp/infer-specs [ret] ret-key)})
                                        ret))])))
                       fn-var-info)]
    (doseq [[var f] new-defs]
      (alter-var-root var (constantly f)))
    (try
      (let [ret (apply (deref var) args)]
        {:derived-specs (deref derived-specs)
         :ret ret})
      (finally
        (doseq [[var _ f] fn-var-info]
          (alter-var-root var (constantly f)))))))