Genshin Wish History URL finder for PlayCover

README.md

For use with https://paimon.moe/wish/import

Steps:

1. Run Genshin Impact in PlayCover
2. Log in, open the Wish menu, open Wish History, and wait for the first page to load
3. Open a terminal (such as Terminal.app or iTerm2)
4. In the terminal, run the command

• curl -s 'https://gist.githubusercontent.com/noxiousninja/2b0eb04c521d7e937f44db38f83733bf/raw/get-genshin-wish-link.sh' | zsh

The script is below, if you wish to review it before use. The URL in the command above is from the "Raw" link for the file, but modified to always go to the latest version.

Tested with:

• Genshin Impact 4.7
• America server account
• PlayCover nightly 765 (June 5, 2024)
• macOS 14.5

Technical Info

Paimon.moe import code

I think this is the code used for the importing: https://github.com/MadeBaruna/paimon-moe/blob/1d1a99c3923388a2eb47eda1145a6ba9617be406/src/routes/wish/import.svelte#L172C18-L384

It uses a server-side proxy to get around CORS, but all the logic seems to be client-side.

Example URLs

Genshin 4.7, America server:

https://gs.hoyoverse.com/genshin/event/e20190909gacha-v3/index.html?win_mode=fullscreen&authkey_ver=1&sign_type=2&auth_appid=webview_gacha&init_type=301&gacha_id=BLAHBLAH&timestamp=1717544570&lang=en&device_type=mobile&game_version=OSRELiOS4.7.0_R23760009_S24199308_D24108674&plat_type=ios&region=os_usa&authkey=BLAHBLAH&game_biz=hk4e_global

get-genshin-wish-link.sh

#!/usr/bin/env zsh
set -euo pipefail

# https://gist.github.com/noxiousninja/2b0eb04c521d7e937f44db38f83733bf

readonly GENSHIN_CACHE_DIR="${HOME}/Library/Containers/com.miHoYo.GenshinImpact/Data/Library/Caches/WebKit/NetworkCache/Version 16/Records"

if [[ ! -d "${GENSHIN_CACHE_DIR}" ]]; then
    printf -- $'ERROR: Couldn\'t find Genshin Impact/PlayCover cache directory:' >&2
    printf -- '%s' "${GENSHIN_CACHE_DIR}" >&2
    exit 1
fi

# find all record files which were modified in the past hour, most recently modified first
# ignore Finder's metadata files (.DS_Store)
find_output="$(find "${GENSHIN_CACHE_DIR}" -type f -mtime -1h ! -iname '.DS_Store' -print0 | xargs -0 ls -t1 )"
if [[ -z "$find_output" ]]; then
    printf -- $'ERROR: Couldn\'t find any Genshin network cache files!\n' >&2
    printf -- $'Are you sure you opened the wishing history screen recently?\n' >&2
    exit 2
fi
# split the output lines into an array
files=("${(@f)${find_output}}")
printf -- '# candidate files: %d\n\n' "${#files[@]}"

# find the first file which matches the URL pattern
# and save the matching string
match_file=''
url_pattern='https://.+gacha.+authkey.+game_biz.+'
for f in $files; do
    # normally, grep exits with code 1 if there are no matches
    # we use || true to force it to exit with code 0 and then just check if the output was empty
    #
    # -m1 to limit grep to the first match in the file, since there may be a second that ends with #/log
    # that we don't care about (either works with paimon.moe, so even if they get reordered, it wouldn't matter)
    output="$(strings "${f}" | grep -m1 -E "${url_pattern}" || true)"
    if [[ ! -z "${output}" ]]; then
        match_file="${f}"
        break
    fi
done

if [[ -z "${match_file}" ]]; then
    printf -- 'ERROR: URL not found!\n' >&2
    printf -- $'Are you sure you opened the wishing history screen?\n' >&2
    printf -- $'If so, the script may need to be updated.\n' >&2
    exit 3
else
    printf -- 'Found Wish History URL in file:\n'
    printf -- '%s\n\n' "${match_file}"
    stat -x "${match_file}"
    printf -- '\n'
    printf -- '%s\n' "${output}"
    pbcopy < <(echo -n "${output}")
    printf -- '\n\nURL copied to clipboard!\n'
    printf -- 'Go to https://paimon.moe/wish/import and paste it in\n'
fi