Simple substitute for Outputable

Indentable.hs

{-# LANGUAGE OverloadedStrings #-}

module GHC.Utils.Indentable
  ( IndentedBuilder
  , Indentation
  , newline
  , indentBy
  , indent
  , (<+>)
  )

where

import GHC.Prelude

import Data.ByteString.Builder
import Data.Monoid
import Data.Semigroup
import Data.String

type Indentation = Builder

newtype IndentedBuilder = IB (Indentation -> Builder)

newline :: IndentedBuilder
newline = IB $ \indent -> "\n" <> indent

instance Semigroup IndentedBuilder where
   IB f <> IB f' = IB $ \indent -> f indent <> f' indent

instance IsString IndentedBuilder where
   fromString s = IB $ const (fromString s)

instance Monoid IndentedBuilder where
   mempty = IB $ const mempty

indentBy :: Indentation -> IndentedBuilder -> IndentedBuilder
indentBy moreIndent (IB f) = IB (\indent -> f (indent <> moreIndent))

indent :: Indentation -> IndentedBuilder -> Builder
indent indentation (IB f) = f indentation

(<+>) :: IndentedBuilder -> IndentedBuilder -> IndentedBuilder
s <+> s' = s <> " " <> s'