sibilant defclass sample

output of sample_defclass

maybe:python-sibilant siege$ sibilant sample_defclass.lspy
Tom says: Hey there, Sally
Sally says: What's up, Tom
Tom says: Good-bye!
Sally says: Good-bye!

sample_defclass.lspy

(defmacro method (name params . &body)
  `(let ((*method* (lambda ,params ,@&body))
	 (*name* ,(str name)))
     (setf *method* __name__ *name*)
     (set-item *members* *name* *method*)))


(defmacro class (name bases . &body)
  `(let ((*members* (dict))
	 (*name* ,(str name)))
     ,@&body
     (type *name*
	   (make-tuple ,@bases)
	   *members*)))


(defmacro defclass (name bases . &body)
  `(define ,name (class ,name ,bases ,@&body)))


(defclass Person (object)

  (method __init__ (self name)
	  (set! self.name name))

  (method say (self . &messages)
	  (apply print (cons self.name "says:" &messages)))

  (method goodbye (self)
	  (self.say "Good-bye!"))

  (method greet (self buddy)
	  (self.say "Hey there," buddy.name)
	  (buddy.respond self))

  (method respond (self buddy)
	  (self.say "What's up," buddy.name)))


(defmacro defperson (name)
  `(define ,name (Person ,(str name))))


(defperson Tom)
(defperson Sally)

(Tom.greet Sally)
(Tom.goodbye)
(Sally.goodbye)


;; The end.