PKBUILD to build conky as per https://github.com/brndnmtthws/conky/issues/923#issuecomment-604872374

PKGBUILD

# Maintainer: ohnonot-github

pkgname=conky
pkgver=1.11.3
pkgrel=99
pkgdesc='Lightweight system monitor for X'
url='https://github.com/brndnmtthws/conky'
license=('BSD' 'GPL')
arch=('x86_64')
makedepends=('cmake' 'docbook2x' 'docbook-xsl' 'man-db' 'git')
depends=('glib2' 'lua' 'libxdamage' 'libxinerama' 'libxft'
         'imlib2' 'libxml2' )
source=("https://github.com/brndnmtthws/conky/archive/v${pkgver}.tar.gz")
sha256sums=('0140e749537d4d05bf33fbac436e54756faa26021e16f2bca418e9eeea724eb4')
options=('!strip' 'debug')

build() {
	cd "${srcdir}/${pkgname}-${pkgver}"

	cmake \
		-D CMAKE_BUILD_TYPE=Release \
		-D MAINTAINER_MODE=ON \
		-D BUILD_DOCS=ON \
        -D BUILD_AUDACIOUS=OFF \
		-D BUILD_WLAN=OFF \
		-D BUILD_XDBE=ON \
		-D BUILD_XSHAPE=ON \
		-D BUILD_IMLIB2=ON \
		-D BUILD_CURL=ON \
		-D BUILD_RSS=ON \
		-D BUILD_NVIDIA=OFF \
		-D BUILD_WEATHER_METAR=OFF \
		-D BUILD_PULSEAUDIO=OFF \
		-D BUILD_JOURNAL=ON \
		-D CMAKE_INSTALL_PREFIX=/usr \
        -D BUILD_BUILTIN_CONFIG=OFF \
        -D BUILD_CMUS=OFF \
        -D BUILD_HDDTEMP=ON \
        -D BUILD_HTTP=ON \
        -D BUILD_I18N=OFF \
        -D BUILD_IBM=OFF \
        -D BUILD_MOC=ON \
        -D BUILD_MPD=OFF \
        -D BUILD_NCURSES=OFF \
        -D BUILD_OLD_CONFIG=OFF \
        -D DEFAULTNETDEV=enp1s0 \
        -D DEFAULT_TEXT_BUFFER_SIZE=256 \
        -D MAX_NET_INTERFACES=64 \
        -D MAX_USER_TEXT_DEFAULT=16384 \
        .

	make
}

package() {
	cd "${srcdir}/${pkgname}-${pkgver}"
	make DESTDIR="${pkgdir}" install
	install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
	install -Dm644 extras/nano/conky.nanorc "${pkgdir}"/usr/share/nano/conky.nanorc
	install -Dm644 extras/vim/syntax/conkyrc.vim "${pkgdir}"/usr/share/vim/vimfiles/syntax/conkyrc.vim
	install -Dm644 extras/vim/ftdetect/conkyrc.vim "${pkgdir}"/usr/share/vim/vimfiles/ftdetect/conkyrc.vim
}