Super Factory Manager scripts

ae2_processors.sfml

name "AE2 Processors"

-- Silicon to stage_1
every 20 ticks do
    input "ftbic:silicon"
    from stage_0
    output retain 1 to each stage_1 north side
end

-- Redstone to stage_3
every 20 ticks do
    input "minecraft:redstone"
    from stage_0
    output retain 1 to each stage_3 north side
end

-- Printed Silicon to stage_3
every 20 ticks do
    input "ae2:printed_silicon"
    from stage_0, stage_1
    output retain 1 to each stage_3 bottom side
end

-- Printed logic processor
every 20 ticks do
    input "minecraft:gold_ingot"
    from stage_0
    output to stage_2_logic north side
end

-- Printed calculation processor
every 20 ticks do
    input "ae2:certus_quartz_crystal"
    from stage_0
    output to stage_2_calculation north side
end

-- Printed engineering processor
every 20 ticks do
    input "minecraft:diamond"
    from stage_0
    output to stage_2_engineering north side
end

-- Assemble processors. Stage 2 (printed) to stage_3
every 20 ticks do
    input "ae2:printed_logic_processor", "ae2:printed_calculation_processor", "ae2:printed_engineering_processor"
    from stage_0, stage_2 north side
    output retain 1 to each stage_3 top side
end

-- Move processors to output
every 20 ticks do
    input "ae2:logic_processor", "ae2:calculation_processor", "ae2:engineering_processor"
    from stage_3 north side
    output to stage_4
end

power_gen.sfml

name "Power Gen"

-- Logs to smelters
every 20 ticks do
    input "minecraft:spruce_log"
    from log_storage bottom side
    output to each smelter top side
end

-- Charcoal to storage
every 20 ticks do
    input "minecraft:charcoal"
    from smelter bottom side
    output to charcoal_storage top side
end

-- Charcoal from storage to generators
every 20 ticks do
    input "mekanism:block_charcoal"
    from charcoal_storage
    output retain 1 to each generator
end