Homophonic quotients of free groups

homophony.g

# This file contains the GAP input needed to verify the result of the paper
# Mestre, Jean-François; Schoof, René; Washington, Lawrence; Zagier, Don
# Quotients homophones des groupes libres. (French) [Homophonic quotients of 
# free groups] Experiment. Math. 2 (1993), no. 3, 153--155 
# (http://eudml.org/doc/233741) with respect to the English language.

F:=FreeGroup("a","b","c","d","e","f","g","h","i","j","k","l","m",
             "n","o","p","q","r","s","t","u","v","w","x","y","z");
             
AssignGeneratorVariables(F);

pairs:=[ 
"bye=by",          # e=1
"lead=led",        # a=1
"maid=made",       # mid=md => i=1
"sow=sew",         # o=e=1
"buy=by",          # u=1
"sow=so",          # w=1
"lye=lie",         # y=1
"hour=our",        # h=1 
"knight=night",    # k=1
"damn=dam",        # n=1
"psalter=salter",  # p=1
"plumb=plum",      # b=1
"bass=base",       # s=1
"butt=but",        # t=1
"tolled=told",     # l=1
"barred=bard",     # r=1
"dammed=damned",   # m=1
"chased=chaste",   # d=1
"sign=sine",       # g=1
"daze=days",       # z=1
"cite=sight",      # c=1
"jeans=genes",     # j=1
"queue=cue",       # q=1
"tax=tacks",       # x=1
# "ruff=rough" ],  # f=1, we need not this relation used in the paper
"phase=faze",      # f=1
"chivvy=chivy"];   # v=1

rels:=List( pairs, r -> ParseRelators(GeneratorsOfGroup(F),r)[1]);
G:=F/rels;
Size(G);