Super simple scope capture macro for CLJS. Hoping to make it simpler.

dbg.cljc

(ns can-i-spy.dbg
  (:require [clojure.spec.alpha :as s]))

(defonce dbg-meta (atom {}))

#?(:cljs (defonce dbg-data (atom {})))

(defmacro spy
  [k]
  (let [symbols (keys (:locals &env))
        locals (zipmap (map (fn [sym] `(quote ~sym)) symbols) symbols)
        location (-> &form meta)]
    (swap! dbg-meta update k conj {:location location :symbols symbols})
    `(do (swap! dbg-data update ~k conj {:location ~location :locals ~locals}) nil)))

(defmacro locals
  [k]
  `(:locals (first (get @dbg-data ~k))))

(defmacro post-mortem
  [k]
  (let [{:keys [symbols location] :as data} (first (get @dbg-meta k))
        def-sym (fn [sym]
                  `(let [m# (first (get @dbg-data ~k))
                         val# (get (:locals m#) '~sym)]
                     (def ~sym val#)))]
    (s/assert (s/coll-of symbol?) symbols)
    (s/assert map? location)
    `(let [m# (first (get @dbg-data ~k))]
       (do (println "Set up post-mortem of line" (:line (:location m#)) "of" (:file (:location m#)))
           (println "Symbols: " ~(pr-str symbols))
           ~@(map def-sym symbols)
           m#))))