why don't you just use range? :")

example3COUNT.chpl

use RangeChunk;


// serial
iter count(start: int, step: int, end: int) { 
  for i in start..end by step do
    yield i;
}


// standalone
pragma "no doc"
iter count(param tag:iterKind, start: int, step: int, end: int)
    where tag == iterKind.standalone {
    var numTasks = here.maxTaskPar;
    coforall tid in 0..#numTasks {
        var nowRange = chunk(start..end, numTasks, tid);
        for i in nowRange {
            if (i - start) % step == 0 {        // we need to do this because
                yield i;                        // we need a reference point
            }                                   // for every chunk
        }
    }
}


// leader
pragma "no doc"
iter count(param tag: iterKind, start: int, step: int, end: int) 
    where tag == iterKind.leader {
    var numTasks = here.maxTaskPar;
    coforall tid in 0..#numTasks {
        var nowRange = chunk(start..end, numTasks, tid).translate(-start); 
        yield (nowRange,);
    }
}


// follower
pragma "no doc"
iter count(param tag: iterKind, start: int, step: int, end: int, followThis)
    where tag == iterKind.follower && followThis.size == 1 {
    var nowIter = followThis(1).translate(start);
    for i in nowIter {
        if (i - start) % step == 0 {        // we need to do this because
            yield i;                        // we need a reference point
        }                                   // for every chunk
    }
}




// serial

for i in count(7,2,18){
    writeln(i);
}


writeln("--------");

// parallel

forall i in count(7,2,18) {
    writeln(i);
}