Created
December 19, 2018 03:29
-
-
Save oneleo/a0f913b21b6b18d831fd62d3d3171d2b to your computer and use it in GitHub Desktop.
Created using remix-ide: Realtime Ethereum Contract Compiler and Runtime. Load this file by pasting this gists URL or ID at https://remix.ethereum.org/#version=soljson-v0.5.1+commit.c8a2cb62.js&optimize=true&gist=
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
pragma solidity >=0.4.24; | |
/** | |
* Utility library of inline functions on addresses | |
*/ | |
library Address { | |
/** | |
* Returns whether the target address is a contract | |
* 回傳目標地址是否為合約 | |
* @dev This function will return false if invoked during the constructor of a contract, | |
* as the code is not actually created until after the constructor finishes. | |
* 如果在合約的建構函數中呼叫此函數將返回 false,因為在建構函數完成之後才會實際創建程式碼。 | |
* @param account address of the account to check | |
* 要檢查的帳戶地址。 | |
* @return whether the target address is a contract | |
* 目標地址是否是合約。 | |
*/ | |
function isContract(address account) internal view returns (bool) { | |
uint256 size; | |
// XXX Currently there is no better way to check if there is a contract in an address | |
// than to check the size of the code at that address. | |
// 目前沒有更好的方法來檢查地址中是否為合約,而不是只檢查該地址的代碼大小。 | |
// See https://ethereum.stackexchange.com/a/14016/36603 | |
// for more details about how this works. | |
// TODO Check this again before the Serenity release, because all addresses will be | |
// contracts then. | |
// 在 Serenity 發布之前再次檢查,因為所有地址都是合約。 | |
// solium-disable-next-line security/no-inline-assembly | |
assembly { size := extcodesize(account) } | |
return size > 0; | |
} | |
} |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
pragma solidity >=0.4.24; | |
import "./IERC165.sol"; | |
/** | |
* @title ERC165 | |
* @author Matt Condon (@shrugs) | |
* @dev Implements ERC165 using a lookup table. | |
*/ | |
contract ERC165 is IERC165 { | |
bytes4 private constant _InterfaceId_ERC165 = 0x01ffc9a7; | |
/** | |
* 0x01ffc9a7 === | |
* bytes4(keccak256('supportsInterface(bytes4)')) | |
*/ | |
/** | |
* @dev a mapping of interface id to whether or not it's supported | |
*/ | |
mapping(bytes4 => bool) private _supportedInterfaces; | |
/** | |
* @dev A contract implementing SupportsInterfaceWithLookup | |
* implement ERC165 itself | |
*/ | |
constructor () internal { | |
_registerInterface(_InterfaceId_ERC165); | |
} | |
/** | |
* @dev implement supportsInterface(bytes4) using a lookup table | |
*/ | |
function supportsInterface(bytes4 interfaceId) external view returns (bool) { | |
return _supportedInterfaces[interfaceId]; | |
} | |
/** | |
* @dev internal method for registering an interface | |
*/ | |
function _registerInterface(bytes4 interfaceId) internal { | |
require(interfaceId != 0xffffffff); | |
_supportedInterfaces[interfaceId] = true; | |
} | |
} |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
pragma solidity >=0.4.24; | |
import "./IERC721.sol"; | |
import "./IERC721Receiver.sol"; | |
import "./SafeMath.sol"; | |
import "./Address.sol"; | |
import "./ERC165.sol"; | |
/** | |
* @title ERC721 Non-Fungible Token Standard basic implementation | |
* ERC721 不可替代代幣(NFT)標準實現。 | |
* @dev see https://github.com/ethereum/EIPs/blob/master/EIPS/eip-721.md | |
*/ | |
contract ERC721 is ERC165, IERC721 { | |
using SafeMath for uint256; | |
using Address for address; | |
// Equals to `bytes4(keccak256("onERC721Received(address,address,uint256,bytes)"))` | |
// which can be also obtained as `IERC721Receiver(0).onERC721Received.selector` | |
bytes4 private constant _ERC721_RECEIVED = 0x150b7a02; | |
// Mapping from token ID to owner | |
// 從代幣 ID 映射到擁有者。 | |
mapping (uint256 => address) private _tokenOwner; | |
// Mapping from token ID to approved address | |
// 從代幣 ID 映射到批准的地址。 | |
mapping (uint256 => address) private _tokenApprovals; | |
// Mapping from owner to number of owned token | |
// 從擁有者映射到擁有代幣的數量。 | |
mapping (address => uint256) private _ownedTokensCount; | |
// Mapping from owner to operator approvals | |
// 從擁有者映射到是否允許 operator 代為操作擁有者所有代幣的轉移批准。 | |
mapping (address => mapping (address => bool)) private _operatorApprovals; | |
bytes4 private constant _InterfaceId_ERC721 = 0x80ac58cd; | |
/* | |
* 0x80ac58cd === | |
* bytes4(keccak256('balanceOf(address)')) ^ | |
* bytes4(keccak256('ownerOf(uint256)')) ^ | |
* bytes4(keccak256('approve(address,uint256)')) ^ | |
* bytes4(keccak256('getApproved(uint256)')) ^ | |
* bytes4(keccak256('setApprovalForAll(address,bool)')) ^ | |
* bytes4(keccak256('isApprovedForAll(address,address)')) ^ | |
* bytes4(keccak256('transferFrom(address,address,uint256)')) ^ | |
* bytes4(keccak256('safeTransferFrom(address,address,uint256)')) ^ | |
* bytes4(keccak256('safeTransferFrom(address,address,uint256,bytes)')) | |
*/ | |
constructor () public { | |
// register the supported interfaces to conform to ERC721 via ERC165 | |
// 透過 ERC165 註冊已支援的介面以符合 ERC721。 | |
_registerInterface(_InterfaceId_ERC721); | |
} | |
/** | |
* @dev Gets the balance of the specified address | |
* 取得指定地址的餘額。 | |
* @param owner address to query the balance of | |
* 擁有者地址查詢餘額。 | |
* @return uint256 representing the amount owned by the passed address | |
* 回傳 uint256:表示傳遞的地址所擁有的數量。 | |
*/ | |
function balanceOf(address owner) public view returns (uint256) { | |
require(owner != address(0)); | |
return _ownedTokensCount[owner]; | |
} | |
/** | |
* @dev Gets the owner of the specified token ID | |
* 取得指定代幣 ID 的擁有者。 | |
* @param tokenId uint256 ID of the token to query the owner of | |
* tokenId uint256 查詢擁有者的代幣 ID。 | |
* @return owner address currently marked as the owner of the given token ID | |
* 回傳 address:此地址為目前標記為給定代幣 ID 的擁有者。 | |
*/ | |
function ownerOf(uint256 tokenId) public view returns (address) { | |
address owner = _tokenOwner[tokenId]; | |
require(owner != address(0)); | |
return owner; | |
} | |
/** | |
* @dev Approves another address to transfer the given token ID | |
* The zero address indicates there is no approved address. | |
* There can only be one approved address per token at a given time. | |
* Can only be called by the token owner or an approved operator. | |
* 批准另一個地址來轉移給定的代幣 ID。0x0 地址表示沒有批准給任何地址。 | |
* 在給定時間內,每個代幣僅能一個已批准的地址。 只能由代幣擁有者或經過批准的 operator 呼叫。 | |
* @param to address to be approved for the given token ID | |
* 參數 to address:可獲得指定的代幣 ID 的 地址。 | |
* @param tokenId uint256 ID of the token to be approved | |
* 參數 tokenId uint256:要批准的代幣 ID。 | |
*/ | |
function approve(address to, uint256 tokenId) public { | |
address owner = ownerOf(tokenId); | |
require(to != owner); | |
require(msg.sender == owner || isApprovedForAll(owner, msg.sender)); | |
_tokenApprovals[tokenId] = to; | |
emit Approval(owner, to, tokenId); | |
} | |
/** | |
* @dev Gets the approved address for a token ID, or zero if no address set | |
* Reverts if the token ID does not exist. | |
* 獲取代幣 ID 的已批准地址,如果沒有設置地址,則返回 0x0 地址。如果代幣 ID 不存在,則返回錯誤。 | |
* @param tokenId uint256 ID of the token to query the approval of | |
* 參數 tokenId uint256:用於查詢批准的代幣的 ID。 | |
* @return address currently approved for the given token ID | |
* 回傳 address:目前已獲批准可取得此代幣 ID 的地址。 | |
*/ | |
function getApproved(uint256 tokenId) public view returns (address) { | |
require(_exists(tokenId)); | |
return _tokenApprovals[tokenId]; | |
} | |
/** | |
* @dev Sets or unsets the approval of a given operator | |
* An operator is allowed to transfer all tokens of the sender on their behalf | |
* 設置或取消允許 operator 代為僺作 sender 所有代幣的轉移批准。 | |
* @param to operator address to set the approval | |
* 參數 to operator:設置允許代替 sender 所有代幣轉移批准的 operator。 | |
* @param approved representing the status of the approval to be set | |
* 參數 approved:設置 operator 是否允許代替 sender 所有代幣轉移批准。 | |
*/ | |
function setApprovalForAll(address to, bool approved) public { | |
require(to != msg.sender); | |
_operatorApprovals[msg.sender][to] = approved; | |
emit ApprovalForAll(msg.sender, to, approved); | |
} | |
/** | |
* @dev Tells whether an operator is approved by a given owner | |
* @param owner owner address which you want to query the approval of | |
* @param operator operator address which you want to query the approval of | |
* @return bool whether the given operator is approved by the given owner | |
*/ | |
function isApprovedForAll(address owner, address operator) public view returns (bool) { | |
return _operatorApprovals[owner][operator]; | |
} | |
/** | |
* @dev Transfers the ownership of a given token ID to another address | |
* Usage of this method is discouraged, use `safeTransferFrom` whenever possible | |
* Requires the msg sender to be the owner, approved, or operator | |
* @param from current owner of the token | |
* @param to address to receive the ownership of the given token ID | |
* @param tokenId uint256 ID of the token to be transferred | |
*/ | |
function transferFrom(address from, address to, uint256 tokenId) public { | |
require(_isApprovedOrOwner(msg.sender, tokenId)); | |
_transferFrom(from, to, tokenId); | |
} | |
/** | |
* @dev Safely transfers the ownership of a given token ID to another address | |
* If the target address is a contract, it must implement `onERC721Received`, | |
* which is called upon a safe transfer, and return the magic value | |
* `bytes4(keccak256("onERC721Received(address,address,uint256,bytes)"))`; otherwise, | |
* the transfer is reverted. | |
* | |
* Requires the msg sender to be the owner, approved, or operator | |
* @param from current owner of the token | |
* @param to address to receive the ownership of the given token ID | |
* @param tokenId uint256 ID of the token to be transferred | |
*/ | |
function safeTransferFrom(address from, address to, uint256 tokenId) public { | |
// solium-disable-next-line arg-overflow | |
safeTransferFrom(from, to, tokenId, ""); | |
} | |
/** | |
* @dev Safely transfers the ownership of a given token ID to another address | |
* If the target address is a contract, it must implement `onERC721Received`, | |
* which is called upon a safe transfer, and return the magic value | |
* `bytes4(keccak256("onERC721Received(address,address,uint256,bytes)"))`; otherwise, | |
* the transfer is reverted. | |
* Requires the msg sender to be the owner, approved, or operator | |
* @param from current owner of the token | |
* @param to address to receive the ownership of the given token ID | |
* @param tokenId uint256 ID of the token to be transferred | |
* @param _data bytes data to send along with a safe transfer check | |
*/ | |
function safeTransferFrom(address from, address to, uint256 tokenId, bytes memory _data) public { | |
transferFrom(from, to, tokenId); | |
// solium-disable-next-line arg-overflow | |
require(_checkOnERC721Received(from, to, tokenId, _data)); | |
} | |
/** | |
* @dev Returns whether the specified token exists | |
* @param tokenId uint256 ID of the token to query the existence of | |
* @return whether the token exists | |
*/ | |
function _exists(uint256 tokenId) internal view returns (bool) { | |
address owner = _tokenOwner[tokenId]; | |
return owner != address(0); | |
} | |
/** | |
* @dev Returns whether the given spender can transfer a given token ID | |
* @param spender address of the spender to query | |
* @param tokenId uint256 ID of the token to be transferred | |
* @return bool whether the msg.sender is approved for the given token ID, | |
* is an operator of the owner, or is the owner of the token | |
*/ | |
function _isApprovedOrOwner(address spender, uint256 tokenId) internal view returns (bool) { | |
address owner = ownerOf(tokenId); | |
// Disable solium check because of | |
// https://github.com/duaraghav8/Solium/issues/175 | |
// solium-disable-next-line operator-whitespace | |
return (spender == owner || getApproved(tokenId) == spender || isApprovedForAll(owner, spender)); | |
} | |
/** | |
* @dev Internal function to mint a new token | |
* Reverts if the given token ID already exists | |
* @param to The address that will own the minted token | |
* @param tokenId uint256 ID of the token to be minted | |
*/ | |
function _mint(address to, uint256 tokenId) internal { | |
require(to != address(0)); | |
require(!_exists(tokenId)); | |
_tokenOwner[tokenId] = to; | |
_ownedTokensCount[to] = _ownedTokensCount[to].add(1); | |
emit Transfer(address(0), to, tokenId); | |
} | |
/** | |
* @dev Internal function to burn a specific token | |
* Reverts if the token does not exist | |
* Deprecated, use _burn(uint256) instead. | |
* @param owner owner of the token to burn | |
* @param tokenId uint256 ID of the token being burned | |
*/ | |
function _burn(address owner, uint256 tokenId) internal { | |
require(ownerOf(tokenId) == owner); | |
_clearApproval(tokenId); | |
_ownedTokensCount[owner] = _ownedTokensCount[owner].sub(1); | |
_tokenOwner[tokenId] = address(0); | |
emit Transfer(owner, address(0), tokenId); | |
} | |
/** | |
* @dev Internal function to burn a specific token | |
* Reverts if the token does not exist | |
* @param tokenId uint256 ID of the token being burned | |
*/ | |
function _burn(uint256 tokenId) internal { | |
_burn(ownerOf(tokenId), tokenId); | |
} | |
/** | |
* @dev Internal function to transfer ownership of a given token ID to another address. | |
* As opposed to transferFrom, this imposes no restrictions on msg.sender. | |
* @param from current owner of the token | |
* @param to address to receive the ownership of the given token ID | |
* @param tokenId uint256 ID of the token to be transferred | |
*/ | |
function _transferFrom(address from, address to, uint256 tokenId) internal { | |
require(ownerOf(tokenId) == from); | |
require(to != address(0)); | |
_clearApproval(tokenId); | |
_ownedTokensCount[from] = _ownedTokensCount[from].sub(1); | |
_ownedTokensCount[to] = _ownedTokensCount[to].add(1); | |
_tokenOwner[tokenId] = to; | |
emit Transfer(from, to, tokenId); | |
} | |
/** | |
* @dev Internal function to invoke `onERC721Received` on a target address | |
* The call is not executed if the target address is not a contract | |
* @param from address representing the previous owner of the given token ID | |
* @param to target address that will receive the tokens | |
* @param tokenId uint256 ID of the token to be transferred | |
* @param _data bytes optional data to send along with the call | |
* @return whether the call correctly returned the expected magic value | |
*/ | |
function _checkOnERC721Received(address from, address to, uint256 tokenId, bytes memory _data) internal returns (bool) { | |
if (!to.isContract()) { | |
return true; | |
} | |
bytes4 retval = IERC721Receiver(to).onERC721Received(msg.sender, from, tokenId, _data); | |
return (retval == _ERC721_RECEIVED); | |
} | |
/** | |
* @dev Private function to clear current approval of a given token ID | |
* @param tokenId uint256 ID of the token to be transferred | |
*/ | |
function _clearApproval(uint256 tokenId) private { | |
if (_tokenApprovals[tokenId] != address(0)) { | |
_tokenApprovals[tokenId] = address(0); | |
} | |
} | |
} |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
pragma solidity >=0.4.24; | |
import "./IERC721Enumerable.sol"; | |
import "./ERC721.sol"; | |
import "./ERC165.sol"; | |
/** | |
* @title ERC-721 Non-Fungible Token with optional enumeration extension logic | |
* @dev See https://github.com/ethereum/EIPs/blob/master/EIPS/eip-721.md | |
*/ | |
contract ERC721Enumerable is ERC165, ERC721, IERC721Enumerable { | |
// Mapping from owner to list of owned token IDs | |
mapping(address => uint256[]) private _ownedTokens; | |
// Mapping from token ID to index of the owner tokens list | |
mapping(uint256 => uint256) private _ownedTokensIndex; | |
// Array with all token ids, used for enumeration | |
uint256[] private _allTokens; | |
// Mapping from token id to position in the allTokens array | |
mapping(uint256 => uint256) private _allTokensIndex; | |
bytes4 private constant _InterfaceId_ERC721Enumerable = 0x780e9d63; | |
/** | |
* 0x780e9d63 === | |
* bytes4(keccak256('totalSupply()')) ^ | |
* bytes4(keccak256('tokenOfOwnerByIndex(address,uint256)')) ^ | |
* bytes4(keccak256('tokenByIndex(uint256)')) | |
*/ | |
/** | |
* @dev Constructor function | |
*/ | |
constructor () public { | |
// register the supported interface to conform to ERC721 via ERC165 | |
_registerInterface(_InterfaceId_ERC721Enumerable); | |
} | |
/** | |
* @dev Gets the token ID at a given index of the tokens list of the requested owner | |
* @param owner address owning the tokens list to be accessed | |
* @param index uint256 representing the index to be accessed of the requested tokens list | |
* @return uint256 token ID at the given index of the tokens list owned by the requested address | |
*/ | |
function tokenOfOwnerByIndex(address owner, uint256 index) public view returns (uint256) { | |
require(index < balanceOf(owner)); | |
return _ownedTokens[owner][index]; | |
} | |
/** | |
* @dev Gets the total amount of tokens stored by the contract | |
* @return uint256 representing the total amount of tokens | |
*/ | |
function totalSupply() public view returns (uint256) { | |
return _allTokens.length; | |
} | |
/** | |
* @dev Gets the token ID at a given index of all the tokens in this contract | |
* Reverts if the index is greater or equal to the total number of tokens | |
* @param index uint256 representing the index to be accessed of the tokens list | |
* @return uint256 token ID at the given index of the tokens list | |
*/ | |
function tokenByIndex(uint256 index) public view returns (uint256) { | |
require(index < totalSupply()); | |
return _allTokens[index]; | |
} | |
/** | |
* @dev Internal function to transfer ownership of a given token ID to another address. | |
* As opposed to transferFrom, this imposes no restrictions on msg.sender. | |
* @param from current owner of the token | |
* @param to address to receive the ownership of the given token ID | |
* @param tokenId uint256 ID of the token to be transferred | |
*/ | |
function _transferFrom(address from, address to, uint256 tokenId) internal { | |
super._transferFrom(from, to, tokenId); | |
_removeTokenFromOwnerEnumeration(from, tokenId); | |
_addTokenToOwnerEnumeration(to, tokenId); | |
} | |
/** | |
* @dev Internal function to mint a new token | |
* Reverts if the given token ID already exists | |
* @param to address the beneficiary that will own the minted token | |
* @param tokenId uint256 ID of the token to be minted | |
*/ | |
function _mint(address to, uint256 tokenId) internal { | |
super._mint(to, tokenId); | |
_addTokenToOwnerEnumeration(to, tokenId); | |
_addTokenToAllTokensEnumeration(tokenId); | |
} | |
/** | |
* @dev Internal function to burn a specific token | |
* Reverts if the token does not exist | |
* Deprecated, use _burn(uint256) instead | |
* @param owner owner of the token to burn | |
* @param tokenId uint256 ID of the token being burned | |
*/ | |
function _burn(address owner, uint256 tokenId) internal { | |
super._burn(owner, tokenId); | |
_removeTokenFromOwnerEnumeration(owner, tokenId); | |
// Since tokenId will be deleted, we can clear its slot in _ownedTokensIndex to trigger a gas refund | |
_ownedTokensIndex[tokenId] = 0; | |
_removeTokenFromAllTokensEnumeration(tokenId); | |
} | |
/** | |
* @dev Gets the list of token IDs of the requested owner | |
* @param owner address owning the tokens | |
* @return uint256[] List of token IDs owned by the requested address | |
*/ | |
function _tokensOfOwner(address owner) internal view returns (uint256[] storage) { | |
return _ownedTokens[owner]; | |
} | |
/** | |
* @dev Private function to add a token to this extension's ownership-tracking data structures. | |
* @param to address representing the new owner of the given token ID | |
* @param tokenId uint256 ID of the token to be added to the tokens list of the given address | |
*/ | |
function _addTokenToOwnerEnumeration(address to, uint256 tokenId) private { | |
_ownedTokensIndex[tokenId] = _ownedTokens[to].length; | |
_ownedTokens[to].push(tokenId); | |
} | |
/** | |
* @dev Private function to add a token to this extension's token tracking data structures. | |
* @param tokenId uint256 ID of the token to be added to the tokens list | |
*/ | |
function _addTokenToAllTokensEnumeration(uint256 tokenId) private { | |
_allTokensIndex[tokenId] = _allTokens.length; | |
_allTokens.push(tokenId); | |
} | |
/** | |
* @dev Private function to remove a token from this extension's ownership-tracking data structures. Note that | |
* while the token is not assigned a new owner, the _ownedTokensIndex mapping is _not_ updated: this allows for | |
* gas optimizations e.g. when performing a transfer operation (avoiding double writes). | |
* This has O(1) time complexity, but alters the order of the _ownedTokens array. | |
* @param from address representing the previous owner of the given token ID | |
* @param tokenId uint256 ID of the token to be removed from the tokens list of the given address | |
*/ | |
function _removeTokenFromOwnerEnumeration(address from, uint256 tokenId) private { | |
// To prevent a gap in from's tokens array, we store the last token in the index of the token to delete, and | |
// then delete the last slot (swap and pop). | |
uint256 lastTokenIndex = _ownedTokens[from].length.sub(1); | |
uint256 tokenIndex = _ownedTokensIndex[tokenId]; | |
// When the token to delete is the last token, the swap operation is unnecessary | |
if (tokenIndex != lastTokenIndex) { | |
uint256 lastTokenId = _ownedTokens[from][lastTokenIndex]; | |
_ownedTokens[from][tokenIndex] = lastTokenId; // Move the last token to the slot of the to-delete token | |
_ownedTokensIndex[lastTokenId] = tokenIndex; // Update the moved token's index | |
} | |
// This also deletes the contents at the last position of the array | |
_ownedTokens[from].length--; | |
// Note that _ownedTokensIndex[tokenId] hasn't been cleared: it still points to the old slot (now occcupied by | |
// lasTokenId, or just over the end of the array if the token was the last one). | |
} | |
/** | |
* @dev Private function to remove a token from this extension's token tracking data structures. | |
* This has O(1) time complexity, but alters the order of the _allTokens array. | |
* @param tokenId uint256 ID of the token to be removed from the tokens list | |
*/ | |
function _removeTokenFromAllTokensEnumeration(uint256 tokenId) private { | |
// To prevent a gap in the tokens array, we store the last token in the index of the token to delete, and | |
// then delete the last slot (swap and pop). | |
uint256 lastTokenIndex = _allTokens.length.sub(1); | |
uint256 tokenIndex = _allTokensIndex[tokenId]; | |
// When the token to delete is the last token, the swap operation is unnecessary. However, since this occurs so | |
// rarely (when the last minted token is burnt) that we still do the swap here to avoid the gas cost of adding | |
// an 'if' statement (like in _removeTokenFromOwnerEnumeration) | |
uint256 lastTokenId = _allTokens[lastTokenIndex]; | |
_allTokens[tokenIndex] = lastTokenId; // Move the last token to the slot of the to-delete token | |
_allTokensIndex[lastTokenId] = tokenIndex; // Update the moved token's index | |
// This also deletes the contents at the last position of the array | |
_allTokens.length--; | |
_allTokensIndex[tokenId] = 0; | |
} | |
} |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
pragma solidity >=0.4.24; | |
import "./ERC721.sol"; | |
import "./ERC721Enumerable.sol"; | |
import "./ERC721Metadata.sol"; | |
/** | |
* @title Full ERC721 Token | |
* This implementation includes all the required and some optional functionality of the ERC721 standard | |
* Moreover, it includes approve all functionality using operator terminology | |
* @dev see https://github.com/ethereum/EIPs/blob/master/EIPS/eip-721.md | |
*/ | |
contract ERC721Full is ERC721, ERC721Enumerable, ERC721Metadata { | |
constructor (string memory name, string memory symbol) ERC721Metadata(name, symbol) public {} | |
} |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
pragma solidity >=0.4.24; | |
import "./ERC721.sol"; | |
import "./IERC721Metadata.sol"; | |
import "./ERC165.sol"; | |
contract ERC721Metadata is ERC165, ERC721, IERC721Metadata { | |
// Token name | |
string private _name; | |
// Token symbol | |
string private _symbol; | |
// Optional mapping for token URIs | |
mapping(uint256 => string) private _tokenURIs; | |
bytes4 private constant InterfaceId_ERC721Metadata = 0x5b5e139f; | |
/** | |
* 0x5b5e139f === | |
* bytes4(keccak256('name()')) ^ | |
* bytes4(keccak256('symbol()')) ^ | |
* bytes4(keccak256('tokenURI(uint256)')) | |
*/ | |
/** | |
* @dev Constructor function | |
*/ | |
constructor (string memory name, string memory symbol) public { | |
_name = name; | |
_symbol = symbol; | |
// register the supported interfaces to conform to ERC721 via ERC165 | |
_registerInterface(InterfaceId_ERC721Metadata); | |
} | |
/** | |
* @dev Gets the token name | |
* @return string representing the token name | |
*/ | |
function name() external view returns (string memory) { | |
return _name; | |
} | |
/** | |
* @dev Gets the token symbol | |
* @return string representing the token symbol | |
*/ | |
function symbol() external view returns (string memory) { | |
return _symbol; | |
} | |
/** | |
* @dev Returns an URI for a given token ID | |
* Throws if the token ID does not exist. May return an empty string. | |
* @param tokenId uint256 ID of the token to query | |
*/ | |
function tokenURI(uint256 tokenId) external view returns (string memory) { | |
require(_exists(tokenId)); | |
return _tokenURIs[tokenId]; | |
} | |
/** | |
* @dev Internal function to set the token URI for a given token | |
* Reverts if the token ID does not exist | |
* @param tokenId uint256 ID of the token to set its URI | |
* @param uri string URI to assign | |
*/ | |
function _setTokenURI(uint256 tokenId, string memory uri) internal { | |
require(_exists(tokenId)); | |
_tokenURIs[tokenId] = uri; | |
} | |
/** | |
* @dev Internal function to burn a specific token | |
* Reverts if the token does not exist | |
* Deprecated, use _burn(uint256) instead | |
* @param owner owner of the token to burn | |
* @param tokenId uint256 ID of the token being burned by the msg.sender | |
*/ | |
function _burn(address owner, uint256 tokenId) internal { | |
super._burn(owner, tokenId); | |
// Clear metadata (if any) | |
if (bytes(_tokenURIs[tokenId]).length != 0) { | |
delete _tokenURIs[tokenId]; | |
} | |
} | |
} |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
pragma solidity >=0.4.24; | |
import "./TicketSale.sol"; | |
contract Hub { | |
mapping (address => bool) admins; | |
mapping (uint256 => address) public eventList; | |
uint256 public events; | |
uint16 public serviceFeeRate = 500; | |
constructor() public { | |
admins[msg.sender] = true; | |
} | |
modifier onlyAdmin() { | |
require(admins[msg.sender] == true, "only admin can access it"); | |
_; | |
} | |
function isAdmin() external view returns (bool) { | |
return admins[msg.sender]; | |
} | |
function setFeeRate(uint16 rate) external onlyAdmin { | |
serviceFeeRate = rate; | |
} | |
function createEvent(string calldata name, uint256 startTime, uint256 dueTime, uint256 price) external { | |
events++; | |
TicketSale ts = new TicketSale(name, address(this), serviceFeeRate, startTime, dueTime, price); | |
ts.setHost(msg.sender); | |
eventList[events] = address(ts); | |
} | |
function withdraw() external onlyAdmin { | |
msg.sender.transfer(address(this).balance); | |
} | |
function getBalance() external view returns (uint256) { | |
return address(this).balance; | |
} | |
function() external payable {} | |
function deposite() external payable {} | |
} |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
pragma solidity >=0.4.24; | |
/** | |
* @title IERC165 | |
* @dev https://github.com/ethereum/EIPs/blob/master/EIPS/eip-165.md | |
*/ | |
interface IERC165 { | |
/** | |
* @notice Query if a contract implements an interface | |
* @param interfaceId The interface identifier, as specified in ERC-165 | |
* @dev Interface identification is specified in ERC-165. This function | |
* uses less than 30,000 gas. | |
*/ | |
function supportsInterface(bytes4 interfaceId) external view returns (bool); | |
} |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
pragma solidity >=0.4.24; | |
import "./IERC165.sol"; | |
/** | |
* @title ERC721 Non-Fungible Token Standard basic interface | |
* @dev see https://github.com/ethereum/EIPs/blob/master/EIPS/eip-721.md | |
*/ | |
contract IERC721 is IERC165 { | |
event Transfer(address indexed from, address indexed to, uint256 indexed tokenId); | |
event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId); | |
event ApprovalForAll(address indexed owner, address indexed operator, bool approved); | |
function balanceOf(address owner) public view returns (uint256 balance); | |
function ownerOf(uint256 tokenId) public view returns (address owner); | |
function approve(address to, uint256 tokenId) public; | |
function getApproved(uint256 tokenId) public view returns (address operator); | |
function setApprovalForAll(address operator, bool _approved) public; | |
function isApprovedForAll(address owner, address operator) public view returns (bool); | |
function transferFrom(address from, address to, uint256 tokenId) public; | |
function safeTransferFrom(address from, address to, uint256 tokenId) public; | |
function safeTransferFrom(address from, address to, uint256 tokenId, bytes memory data) public; | |
} |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
pragma solidity >=0.4.24; | |
import "./IERC721.sol"; | |
/** | |
* @title ERC-721 Non-Fungible Token Standard, optional enumeration extension | |
* @dev See https://github.com/ethereum/EIPs/blob/master/EIPS/eip-721.md | |
*/ | |
contract IERC721Enumerable is IERC721 { | |
function totalSupply() public view returns (uint256); | |
function tokenOfOwnerByIndex(address owner, uint256 index) public view returns (uint256 tokenId); | |
function tokenByIndex(uint256 index) public view returns (uint256); | |
} |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
pragma solidity >=0.4.24; | |
import "./IERC721.sol"; | |
import "./IERC721Enumerable.sol"; | |
import "./IERC721Metadata.sol"; | |
/** | |
* @title ERC-721 Non-Fungible Token Standard, full implementation interface | |
* @dev See https://github.com/ethereum/EIPs/blob/master/EIPS/eip-721.md | |
*/ | |
contract IERC721Full is IERC721, IERC721Enumerable, IERC721Metadata { | |
} |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
pragma solidity >=0.4.24; | |
import "./IERC721.sol"; | |
/** | |
* @title ERC-721 Non-Fungible Token Standard, optional metadata extension | |
* @dev See https://github.com/ethereum/EIPs/blob/master/EIPS/eip-721.md | |
*/ | |
contract IERC721Metadata is IERC721 { | |
function name() external view returns (string memory); | |
function symbol() external view returns (string memory); | |
function tokenURI(uint256 tokenId) external view returns (string memory); | |
} |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
pragma solidity >=0.4.24; | |
/** | |
* @title ERC721 token receiver interface | |
* @dev Interface for any contract that wants to support safeTransfers | |
* from ERC721 asset contracts. | |
*/ | |
contract IERC721Receiver { | |
/** | |
* @notice Handle the receipt of an NFT | |
* @dev The ERC721 smart contract calls this function on the recipient | |
* after a `safeTransfer`. This function MUST return the function selector, | |
* otherwise the caller will revert the transaction. The selector to be | |
* returned can be obtained as `this.onERC721Received.selector`. This | |
* function MAY throw to revert and reject the transfer. | |
* Note: the ERC721 contract address is always the message sender. | |
* @param operator The address which called `safeTransferFrom` function | |
* @param from The address which previously owned the token | |
* @param tokenId The NFT identifier which is being transferred | |
* @param data Additional data with no specified format | |
* @return `bytes4(keccak256("onERC721Received(address,address,uint256,bytes)"))` | |
*/ | |
function onERC721Received(address operator, address from, uint256 tokenId, bytes memory data) public returns (bytes4); | |
} |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
pragma solidity >=0.4.24; | |
contract Migrations { | |
address public owner; | |
uint public last_completed_migration; | |
constructor() public { | |
owner = msg.sender; | |
} | |
modifier restricted() { | |
if (msg.sender == owner) _; | |
} | |
function setCompleted(uint completed) public restricted { | |
last_completed_migration = completed; | |
} | |
function upgrade(address new_address) public restricted { | |
Migrations upgraded = Migrations(new_address); | |
upgraded.setCompleted(last_completed_migration); | |
} | |
} |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
pragma solidity >=0.4.24; | |
/** | |
* @title SafeMath | |
* @dev Math operations with safety checks that revert on error | |
*/ | |
library SafeMath { | |
/** | |
* @dev Multiplies two numbers, reverts on overflow. | |
*/ | |
function mul(uint256 a, uint256 b) internal pure returns (uint256) { | |
// Gas optimization: this is cheaper than requiring 'a' not being zero, but the | |
// benefit is lost if 'b' is also tested. | |
// See: https://github.com/OpenZeppelin/openzeppelin-solidity/pull/522 | |
if (a == 0) { | |
return 0; | |
} | |
uint256 c = a * b; | |
require(c / a == b); | |
return c; | |
} | |
/** | |
* @dev Integer division of two numbers truncating the quotient, reverts on division by zero. | |
*/ | |
function div(uint256 a, uint256 b) internal pure returns (uint256) { | |
// Solidity only automatically asserts when dividing by 0 | |
require(b > 0); | |
uint256 c = a / b; | |
// assert(a == b * c + a % b); // There is no case in which this doesn't hold | |
return c; | |
} | |
/** | |
* @dev Subtracts two numbers, reverts on overflow (i.e. if subtrahend is greater than minuend). | |
*/ | |
function sub(uint256 a, uint256 b) internal pure returns (uint256) { | |
require(b <= a); | |
uint256 c = a - b; | |
return c; | |
} | |
/** | |
* @dev Adds two numbers, reverts on overflow. | |
*/ | |
function add(uint256 a, uint256 b) internal pure returns (uint256) { | |
uint256 c = a + b; | |
require(c >= a); | |
return c; | |
} | |
/** | |
* @dev Divides two numbers and returns the remainder (unsigned integer modulo), | |
* reverts when dividing by zero. | |
*/ | |
function mod(uint256 a, uint256 b) internal pure returns (uint256) { | |
require(b != 0); | |
return a % b; | |
} | |
} |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
pragma solidity >=0.4.24; | |
//import "./ERC721Token.sol"; // Older contract. | |
import "./ERC721Full.sol"; // Newer contract. | |
import "./SafeMath.sol"; | |
import "./Hub.sol"; | |
//contract TicketSale is ERC721Token { | |
contract TicketSale is ERC721Full { | |
using SafeMath for uint8; | |
using SafeMath for uint16; | |
using SafeMath for uint256; | |
Hub hub; | |
mapping(address => bool) public hosts; | |
uint256 public tradings = 0; | |
mapping(uint256 => Trade) public tradingList; | |
mapping(address => uint256) public tradingTicketsOfOwner; | |
mapping(uint256 => bool) public usedTickets; | |
uint256 public tickets = 0; | |
uint256 public price; | |
uint8 public limit = 1; | |
uint256 public maxAttendees = 10; | |
uint16 public tradeFee = 0; | |
uint8 public maxMarkedTickets = 10; | |
uint256 public startTime; | |
uint256 public dueTime; | |
// serviceFeeRatio / 10000 = ratio | |
uint16 public serviceFeeRatio = 100; | |
uint256 public serviceFee = 0; | |
struct Trade { | |
address owner; | |
uint256 ticketId; | |
uint256 value; | |
} | |
constructor (string memory name, address payable hubAddr, uint16 ratio, uint256 _startTime, uint256 _dueTime, uint256 _price) public | |
//ERC721Token(name, name) | |
ERC721Full(name, name) | |
{ | |
hub = Hub(hubAddr); | |
hosts[msg.sender] = true; | |
serviceFeeRatio = ratio; | |
startTime = _startTime; | |
dueTime = _dueTime; | |
price = _price; | |
} | |
modifier onlyHost() { | |
require(hosts[msg.sender] == true, "only host can access it"); | |
_; | |
} | |
function register(uint8 ticketAmount) external payable { | |
require(msg.value >= price.mul(ticketAmount), "not enough value"); | |
require(balanceOf(msg.sender).add(ticketAmount) <= limit, "too many ticket amount"); | |
require(tickets < maxAttendees, "register is ended"); | |
if (startTime != 0) { | |
require(now >= startTime, "ticket sale is not started yet"); | |
} | |
if (dueTime != 0) { | |
require(now <= dueTime, "ticket sale is ended"); | |
} | |
serviceFee = serviceFee.add(msg.value.mul(serviceFeeRatio).div(10000)); | |
for (uint256 index = 0; index < ticketAmount; index++) { | |
tickets++; | |
_mint(msg.sender, tickets); | |
} | |
uint256 rest = msg.value.sub(ticketAmount.mul(price)); | |
if (rest > 0) { | |
msg.sender.transfer(rest); | |
} | |
} | |
function setMaxAttendees(uint256 _maxAttendees) external { | |
maxAttendees = _maxAttendees; | |
} | |
function setHost(address host) external onlyHost { | |
hosts[host] = true; | |
} | |
function setLimit(uint8 _limit) external onlyHost { | |
limit = _limit; | |
} | |
function setPrice(uint256 _price) external onlyHost { | |
price = _price; | |
} | |
function setTradeFee(uint16 _fee) external onlyHost { | |
tradeFee = _fee; | |
} | |
function requestTrading(uint256 ticketId, uint256 value) external { | |
tradings++; | |
tradingList[tradings] = Trade({ticketId: ticketId, value: value, owner: msg.sender}); | |
tradingTicketsOfOwner[msg.sender]++; | |
} | |
function _cancelTrade(uint256 tradeId, address owner) internal { | |
tradingTicketsOfOwner[owner]--; | |
delete tradingList[tradeId]; | |
tradings--; | |
} | |
function cancelTrade(uint256 tradeId) external { | |
Trade memory t = tradingList[tradeId]; | |
require(t.owner == msg.sender, "only owner can cancel trading"); | |
_cancelTrade(tradeId, msg.sender); | |
} | |
function trade(uint256 tradeId) public payable { | |
require(tradingList[tradeId].ticketId != 0, ""); | |
Trade memory t = tradingList[tradeId]; | |
require(t.value <= msg.value, "ticket price is nout enough"); | |
_cancelTrade(t.ticketId, t.owner); | |
//removeTokenFrom(t.owner, t.ticketId); // Older function. | |
//addTokenTo(msg.sender, t.ticketId); // Older function. | |
_transferFrom(t.owner, msg.sender, t.ticketId); // Newer function. | |
} | |
function setUsedTickets(uint256[] calldata ticketIds) external onlyHost { | |
require(ticketIds.length <= maxMarkedTickets, "set too many tickets in the same time"); | |
for (uint8 index = 0; index < ticketIds.length; index++) { | |
usedTickets[ticketIds[index]] = true; | |
} | |
} | |
function isUsedTicket(uint256 ticketId) external view returns (bool) { | |
return usedTickets[ticketId]; | |
} | |
function withdraw() external onlyHost { | |
// BUGGY HERE | |
msg.sender.transfer(address(this).balance.sub(serviceFee)); | |
} | |
function withdrawFee() external { | |
require(address(hub) != address(0), "hub contract does not exist"); | |
require(serviceFee > 0, "service fee is not required"); | |
require(serviceFee <= address(this).balance, "balance is not enough"); | |
hub.deposite.value(serviceFee)(); | |
serviceFee = 0; | |
} | |
} |
Sign up for free
to join this conversation on GitHub.
Already have an account?
Sign in to comment