kill-running-jobs.groovy

import org.jenkinsci.plugins.workflow.job.WorkflowRun
import org.jenkinsci.plugins.workflow.support.steps.StageStepExecution

projectFullName = 'folder/job-name'

dryRun = false

if(!(projectFullName in String)) {
    throw new Exception('PARAMETER ERROR: projectFullName must be a string.')
}

Jenkins.instance.getItemByFullName(projectFullName).builds.each { Run item ->
    if(item.isBuilding()) {
        if(item in WorkflowRun) {
            WorkflowRun run = (WorkflowRun) item
            if(!dryRun) {
                //hard kill
                run.doKill()
                //release pipeline concurrency locks
                StageStepExecution.exit(run)
            }
            println "Killed ${run}"
        } else if(item in FreeStyleBuild) {
            FreeStyleBuild run = (FreeStyleBuild) item
            if(!dryRun) {
                run.executor.interrupt(Result.ABORTED)
            }
            println "Killed ${run}"
        } else {
            println "WARNING: Don't know how to handle ${item.class}"
        }
    }
}