Venue Model

venue.js.coffee

class @Venue extends Spine.Model

  @configure 'Venue', 'address', 'advertUrl', 'email', 'logo', 'latitude', 'longitude', 'name',
    'phoneNumber', 'website', 'shortDescription', 'longDescription',
    'openingHours', 'capacity', 'distance'

  @extend Spine.Model.Local

  @belongsTo 'venueType', 'VenueType'

  @findByIds: (ids) ->
    @ids = ids
    Venue.select (venue) =>
      $.inArray("#{venue.id}", @ids) > -1

  @capacitySort: (v1, v2) ->
    parseFloat(v2.capacity.overall.live) - parseFloat(v1.capacity.overall.live)

  @calculateDistanceFromCurrentLocation: (venues) ->
    for venue in venues
      distance = maps.calculateDistance(new google.maps.LatLng(venue.latitude, venue.longitude))
      venue.updateAttribute 'distance', distance

  @distanceSort: (v1, v2) ->
    parseFloat(v1.distance) - parseFloat(v2.distance)

  @nameSort: (v1, v2) ->
    if v1.name > v2.name then 1
    else if v1.name == v2.name then 0
    else -1

  statsFor: (category, day) =>
    @["capacity"][category][day.toLowerCase()]