Scheduling in Coldfusion without cfschedule, server access, or the Coldfusion Administrator

application.cfc

component {
	this.name = "testingApp";

	public function onApplicationStart() {
		// counter to prove the cron.cfm is firing
		application.counter = 0;
	}

	public function onRequestEnd() {
		// specify an index for the cache
		local.cacheIndex = "cron_process";
		
		// grab an item from the index
		local.cache = cacheGet(local.cacheIndex);

		// cacheGet returns null, so if nothing is in the cache local.cache will not exist
		if (!StructKeyExists(local, "cache")) {
			// we must put the item in the cache BEFORE running the cfhttp, otherwise the cfhttp will trigger another cron hit and we'll be in an infinite loop
			cachePut(local.cacheIndex, "ran at #now()#", CreateTimeSpan(0,0,0,10));

			// send off the cron job to wherever you desire
			local.http = new http(url = "http://www.mywebsite.com/test/basic/caching/cron.cfm", timeout = 1);
			local.http.addParam(type = "header", name = "connection", value = "keep-alive");
			local.http.send();
		}
	}
}

cron.cfm

<!--- increment the counter --->
<cfset Application.counter++>

index.cfm

<!--- check the status of the counter --->
<cfoutput>#Application.counter#</cfoutput>

stop.cfm

<!--- restart the application to clear the timer --->
<cfset ApplicationStop()>