Squidooo Theme for Oh My ZSH

squidooo.zsh-theme

#
# Squidooo Theme for Oh My ZSH
#
# Author:
#   Patrick B <paddyredbeard@gmail.com>
# Source:
#   https://gist.github.com/paddyredbeard/squidooo.zsh-theme
# Usage:
#   1. Install Oh My ZSH - https://ohmyz.sh/
#   2. Download theme file to ~/.oh-my-zsh/custom/themes/squidooo.zsh-theme
#   3. Update ZSH_THEME="squidoo" in ~/.zshrc
#   4. Start a new terminal
# Adapted from:
#   - Kolo and Zahn themes included with oh-my-zsh
#   - JPro-Minimal theme by https://github.com/yujinyuz/
#

autoload -Uz vcs_info

zstyle ':vcs_info:*' stagedstr '%F{green}●'
zstyle ':vcs_info:*' unstagedstr '%F{yellow}●'
zstyle ':vcs_info:*' check-for-changes true
zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat '%b%F{1}:%F{11}%r'
zstyle ':vcs_info:*' enable git svn
theme_precmd () {
    if [[ -z $(git ls-files --other --exclude-standard 2> /dev/null) ]] {
        zstyle ':vcs_info:*' formats ' %F{yellow} %F{green}%b%c%u%B%F{green}'
    } else {
        zstyle ':vcs_info:*' formats ' %F{yellow} %F{green}%b%c%u%B%F{red}●%F{green}'
    }

    vcs_info
}

setopt prompt_subst
PROMPT='%F{yellow}%n%{$reset_color%}\
%F{cyan}@\
%F{013}%m \
%F{063}%c\
%F{green}${vcs_info_msg_0_} \
%B%F{red}:: %{$reset_color%}% '

autoload -U add-zsh-hook
add-zsh-hook precmd theme_precmd