Jenkins: Groovy script to clean up workspace on Jenkins agents

cleanupJenkinsWorkspaces.groovy

import hudson.model.*;
import hudson.util.*;
import jenkins.model.*;
import hudson.FilePath.FileCallable;
import hudson.slaves.OfflineCause;
import hudson.node_monitors.*;


void performCleanup(node, items) {
    for (item in items) {
        def jobName = item.getFullDisplayName()

        println("Cleaning " + jobName)

        if(item instanceof com.cloudbees.hudson.plugins.folder.AbstractFolder) {
            performCleanup(node, item.items)
            continue
        }
    
        if (item.isBuilding()) {
            println(".. job " + jobName + " is currently running, skipped")
            continue
        }

        println(".. wiping out workspaces of job " + jobName)

        def workspacePath = node.getWorkspaceFor(item)

        if (workspacePath == null) {
            println(".... could not get workspace path")
            continue
        }

        println(".... workspace = " + workspacePath)

        def pathAsString = workspacePath.getRemote()

        if (workspacePath.exists()) {
            workspacePath.deleteRecursive()
            println(".... deleted from location " + pathAsString)
        } else {
            println(".... nothing to delete at " + pathAsString)
        }
    }
}


for (node in Jenkins.instance.nodes) {
    def computer = node.toComputer()

    if (computer.getChannel() == null) {
        continue
    }

    def rootPath = node.getRootPath()
    def size = DiskSpaceMonitor.DESCRIPTOR.get(computer).size
    int roundedSize = size / (1024 * 1024 * 1024)

    println("node: " + node.getDisplayName() + ", free space: " + roundedSize + "GB")
    computer.setTemporarilyOffline(true, new hudson.slaves.OfflineCause.ByCLI("disk cleanup"))
  
    performCleanup(node, Jenkins.instance.items)
  
    computer.setTemporarilyOffline(false, null)
}