PKGBUILD for supermin, the artist formerly known as febootstrap.

PKGBUILD.febootstrap

# Former maintainer: Thomas S Hatch <thatch45 (at) Gmail (dot) com>
# Maintainer: Xiao-Long Chen <chillermillerlong at hotmail dot com>
# Contributor: P. A. López-Valencia $(echo PHBhbG9wZXp2IEAgZ21haWwgZG90IGNvbT4K | base64 -d)

pkgname=supermin
pkgver=4.1.1
pkgrel=1
license=('GPL2')
arch=('i686' 'x86_64')
pkgdesc="Tool used to create libguestfs supermin appliances"
url="http://people.redhat.com/~rjones/supermin/"
depends=('wget' 'cpio')
makedepends=('ocaml' 'ocaml-findlib')
provides=('febootstrap')
conflicts=('supermin-git')
source=(http://libguestfs.org/download/${pkgname}/${pkgname}-${pkgver}.tar.gz)

build() {
  cd "${pkgname}-${pkgver}"
  ./configure --prefix=/usr
  make ${MAKEFLAGS}
}

check() {
  cd "${pkgname}-${pkgver}"
  make -k check
}

package () {
  cd "${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}/" install
}

sha512sums=('eff201555ae1caa45dc1a2e9d69249d94b872750ec14df01e923a5bccef7a8d45f5ec00a528f3679c3ae670abeb967d928be032d58c53390c86a6c295d5f6bae')