PKGBUILD for plowshare

PKGBUILD

# Maintainer: speps <speps at aut dot archlinux dot org>
_name=plowshare
pkgname=$_name-git
pkgver=0.2312.ab90f01
pkgrel=1
pkgdesc="Command-line downloader and uploader for Rapidshare, Mediafire and other file sharing websites."
arch=('any')
url="http://code.google.com/p/plowshare/"
license=('GPL')
depends=('curl' 'recode' 'js')
makedepends=('git')
optdepends=('bash-completion: enable bash auto completion'
            'libcaca: ascii display for no X server'
            'tiv: ascii display for no X server'
            'aview: ascii display for no X server')
provides=("$_name")
conflicts=("$_name")
replaces=("$_name-svn")
source=("$_name::git+https://code.google.com/p/$_name/")
md5sums=('SKIP')

pkgver() {
  cd "$srcdir/$_name"
  echo "0.$(git rev-list --count HEAD).$(git describe --always)"
}

package() {
  cd "$srcdir/$_name"
  DESTDIR="$pkgdir/" PREFIX=/usr ./setup.sh install

  # bash completion script
  install -Dm644 etc/$_name.completion \
    "$pkgdir/etc/bash_completion.d/$_name"

  # set CDIR for bash completion
  sed -i "s|local/||" "$pkgdir/etc/bash_completion.d/$_name"
}

# vim:set ts=2 sw=2 et: