Sock Matching Test - triples (PuzzleScript Script)

readme.txt

Play this game by pasting the script in http://www.puzzlescript.net/editor.html

script.txt

title Sock Matching Test - triples
author pancelor
homepage www.twitter.com/pancelor

again_interval 0.05
run_rules_on_level_start
(verbose_logging)

========
OBJECTS
========

Background
LIGHTGREEN GREEN
11111
01111
11101
11111
10111

UnmatchedSock
black yellow grey red
.11..
.33..
.00..
.000.
..00.

MatchedSock
black purple grey blue
.11..
.33..
.00..
.000.
..00.

mNoWallR
yellow

mNoWallL
yellow

mNoWallU
yellow

mNoWallD
yellow

Wall
BROWN DARKBROWN
00010
11111
01000
11111
00010

Player
Black Orange White Blue
.000.
.111.
22222
.333.
.3.3.

Crate
Orange Yellow
00000
0...0
0...0
0...0
00000

JustMatchedSock
transparent

=======
LEGEND
=======

. = Background
# = Wall
P = Player
c = Crate
s = UnmatchedSock

cPushable = UnmatchedSock or Crate or Player
cSock = UnmatchedSock or MatchedSock or JustMatchedSock
cNoWall = mNoWallL or mNoWallR or mNoWallU or mNoWallD
cSockTestBlocker = Wall or Crate or Player or cSock
cSockTestSource = UnmatchedSock or JustMatchedSock

=======
SOUNDS
=======

Crate MOVE 36772507

================
COLLISIONLAYERS
================

Background
Player, Wall, Crate, cSock
cNoWall

======
RULES
======

[ > cPushable | cPushable ] -> [ > cPushable | > cPushable ]

(
shoot out NoWall marks from each sock; when they hit an unmatched sock it becomes matched
)
  (Left)
  late Left [cSockTestSource] -> [cSockTestSource mNoWallL]
  late Left [mNoWallL | no cSockTestBlocker] -> [ | mNoWallL]
  late Left [mNoWallL | UnmatchedSock] -> [ | JustMatchedSock]
  (Right)
  late Right [cSockTestSource] -> [cSockTestSource mNoWallR]
  late Right [mNoWallR | no cSockTestBlocker] -> [ | mNoWallR]
  late Right [mNoWallR | UnmatchedSock] -> [ | JustMatchedSock]
  (Up)
  late Up [cSockTestSource] -> [cSockTestSource mNoWallU]
  late Up [mNoWallU | no cSockTestBlocker] -> [ | mNoWallU]
  late Up [mNoWallU | UnmatchedSock] -> [ | JustMatchedSock]
  (Down)
  late Down [cSockTestSource] -> [cSockTestSource mNoWallD]
  late Down [mNoWallD | no cSockTestBlocker] -> [ | mNoWallD]
  late Down [mNoWallD | UnmatchedSock] -> [ | JustMatchedSock]
late [cNoWall] -> []
late [JustMatchedSock]->[MatchedSock]

==============
WINCONDITIONS
==============

no UnmatchedSock

=======
LEVELS
=======

##################
#........#.......#
#.....P....s..s..#
#...s............#
#....c...#.......#
#.s..#...#...c.###
#.....s..#.s...#s#
#........#.....#s#
##################