cps.scm

(define (passing-arguments arguments names final)
  (assert (= (length arguments) (length names)))
  (match arguments
    (()
     (assert (null? names))
     final)
    ((argument . next)
     (let (((name . names) names))
       (if (compound? argument)
           (passing-arguments next names
                              (passing argument
                                       `(λ (,name) ,final)))
       ;else
           (passing-arguments next names final))))))

(define (passing expression continuation)
  (match expression
         
    (('if <condition> <then> <else>)
     (let ((result (original-name <condition>)))
       (passing <condition> `(λ (,result)
                               (if ,result
                                   ,(passing <then> continuation)
                                   ,(passing <else> continuation))))))

    ((function . arguments)
     (let ((simple-arguments (map (λ (argument)
                                    (if (compound? argument)
                                        (original-name argument)
                                        argument))
                                  arguments)))
       (passing-arguments arguments simple-arguments
                          `(,(passing-function function)
                            ,@simple-arguments
                            ,continuation))))
    (_ ;; value
     `(,continuation ,expression))))