A contract that highlights the difference in behaviour between `CALL` and `DELEGATECALL` in relation to `tx.origin` and `msg.sender`.

TxOriginMsgSenderTest.sol

// SPDX-License-Identifier: WTPFL
pragma solidity 0.8.18;

contract Called {
    function callMe() external view returns (address) {
        // solhint-disable-next-line avoid-tx-origin
        assert(tx.origin == msg.sender);
        return msg.sender;
    }
}

contract Caller {
    function makeCall(address contractAddr) public returns (address) {
        /**
         * @dev Will fail due to `assert(tx.origin == msg.sender)`.
         */
        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returnData) = address(contractAddr).call(
            abi.encodeWithSignature("callMe()")
        );
        require(success, "CALL FAILED");
        address msgSender = abi.decode(returnData, (address));
        return msgSender;
    }

    function makeDelegateCall(address contractAddr) public returns (address) {
        /**
         * @dev Will succeed due to `delegatecall`.
         */
        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returnData) = address(contractAddr)
            .delegatecall(abi.encodeWithSignature("callMe()"));
        require(success, "DELEGATECALL FAILED");
        address msgSender = abi.decode(returnData, (address));
        return msgSender;
    }
}