Created using remix-ide: Realtime Ethereum Contract Compiler and Runtime. Load this file by pasting this gists URL or ID at https://remix.ethereum.org/#version=soljson-v0.8.7+commit.e28d00a7.js&optimize=false&runs=200&gist=

.deps...npm...@openzeppelin...contracts...utils...Address.sol

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");

        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(isContract(target), "Address: delegate call to non-contract");

        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verifies that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}

README.txt

REMIX EXAMPLE PROJECT

Remix example project is present when Remix loads for the very first time or there are no files existing in the File Explorer. 
It contains 3 directories:

1. 'contracts': Holds three contracts with different complexity level, denoted with number prefix in file name.
2. 'scripts': Holds two scripts to deploy a contract. It is explained below.
3. 'tests': Contains one test file for 'Ballot' contract with unit tests in Solidity.

SCRIPTS

The 'scripts' folder contains example async/await scripts for deploying the 'Storage' contract.
For the deployment of any other contract, 'contractName' and 'constructorArgs' should be updated (along with other code if required). 
Scripts have full access to the web3.js and ethers.js libraries.

To run a script, right click on file name in the file explorer and click 'Run'. Remember, Solidity file must already be compiled.

Output from script will appear in remix terminal.

contracts...Bucket.sol

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
import { VRF } from "./VRF.sol";

library BinarySearch {
    struct SearchTicket { // used to binary search
        address user;
        uint256 accumulateTicktes;
    }

    function search(SearchTicket[] storage searches, uint256 tickets) internal view returns (uint256) {
        if (searches.length == 0) {
            return 0;
        }

        uint256 low = 0;
        uint256 high = searches.length;

        while (low < high) {
            // (a + b) / 2 can overflow.
            uint256 mid =  (low & high) + (low ^ high) / 2;

            // Note that mid will always be strictly less than high (i.e. it will be a valid array index)
            // because Math.average rounds down (it does integer division with truncation).
            if (searches[mid].accumulateTicktes > tickets) {
                high = mid;
            } else {
                low = mid + 1;
            }
        }
        return low;
    }
}

contract Bucket {
    using BinarySearch for BinarySearch.SearchTicket[];

    mapping(address=>uint256) public tickets; // total tickets a user deposit
    BinarySearch.SearchTicket[] public searchList; // used to generate whiltelist
    uint256 public rnd; // vrf random number. 0 means not init.
    uint256 public winnerNum; // number of winner

    event AddTickets(address user, uint256 amount);
    event Raffle(address operator, uint256 rnd);

    constructor(uint256 _winnerNum) {
        winnerNum = _winnerNum;
    }

    // get current block's vrf
    function vrf(uint256 blockNo) public view returns(bytes32 _hash) {
        return blockNo == 0 ? VRF.vrf() : VRF.vrf(blockNo);
    }
    // get random number
    function random(bool useVRF) public view returns(uint256) {
        return useVRF ? uint256(VRF.vrf()) : uint256(keccak256(abi.encodePacked(block.timestamp)));
    }

    function randomI(uint256 _rnd, uint256 i) private pure returns(uint256) {
        return uint256(keccak256(abi.encodePacked(_rnd,i)));
    }

    // get whiltelist at the index
    function winnerAt(uint256 i) public view returns(address) {
        uint256 totalTickets = searchList[searchList.length - 1].accumulateTicktes;
        uint256 _rnd = randomI(rnd, i);
        uint256 ticketPosition = _rnd % totalTickets;
        uint256 findIndex = searchList.search(ticketPosition);
        return searchList[findIndex].user;
    }
    // get whiltelist of a round
    function winners() external view returns(address[] memory results) {
        require(rnd != 0, "not raffled");
        results = new address[](winnerNum);
        for(uint256 i = 0; i < winnerNum; i++){
            results[i] = winnerAt(i);
        }
    }

    // user add their tickets
    function addTickets(uint256 amount) external {
        require(rnd == 0, "bucket already closed");

        if(searchList.length > 0 &&  searchList[searchList.length-1].user == msg.sender) {
            searchList[searchList.length-1].accumulateTicktes += amount;
        } else {
            uint256 accumulateTicktes = searchList.length > 0
                ? searchList[searchList.length-1].accumulateTicktes + amount
                : amount;
            searchList.push(BinarySearch.SearchTicket({
                user: msg.sender,
                accumulateTicktes: accumulateTicktes
            }));
        }
        tickets[msg.sender] += amount;
        emit AddTickets(msg.sender, amount);
    }

    // do raffle
    function raffle() external {
        require(rnd == 0, "already raffled");
        rnd = random(true);
        emit Raffle(msg.sender, rnd);
    }
}

contracts...VRF.sol

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

library VRF {
    address constant VRF_NATIVE = address(255);
    // get current block's vrf
    function vrf() internal view returns(bytes32 _hash) {
        return _vrf("");
    }
    // get vrf by block
    function vrf(uint256 blockNo) internal view returns(bytes32 _hash) {
        return _vrf(abi.encodePacked(blockNo));
    }

    function _vrf(bytes memory blockNo) private view returns(bytes32 _hash) {
        (bool success, bytes memory returndata) = VRF_NATIVE.staticcall(blockNo);
        require(success && returndata.length == 32, "invalid vrf");
        assembly {
            _hash := mload(add(32, returndata))
        }
    }
}