android-javadoc

android.libraryVariants.all { variant ->
    javadocs.doFirst {
        classpath += files(android.bootClasspath)
        if (variant.hasProperty('javaCompileProvider')) {
            classpath += files(variant.javaCompileProvider.get().classpath.files)
        } else if (variant.hasProperty('javaCompiler')) {
            classpath += files(variant.javaCompiler.classpath.files)
        }
        // Process AAR dependencies
        def aarDependencies = classpath.filter {
            it.name.endsWith('.aar')
        }
        classpath -= aarDependencies
        aarDependencies.each { aar ->
            // Extract classes.jar from the AAR dependency and add it to the androidJavadocs classpath
            final String outputPath = "${buildDir}/tmp/aarJar/${aar.name.replace('.aar', '.jar')}"
            classpath += files(outputPath)
            // Use a task so the actual extraction only happens before the androidJavadocs task is run
            dependsOn task(name: "extract${aar.name}").doLast {
                MavenPushUtils.extractEntry(aar, 'classes.jar', outputPath)
            }
        }
    }
}