fullCrew.sqf

GetVehicleIcon = {
	params ["_unit"];
	if !(isNull objectParent _unit) exitWith {
		private _crewInfo = ((fullCrew (vehicle _unit)) select {_x select 0 isEqualTo _unit}) select 0;
		_crewInfo params ["", "_role", "_index", "_turretPath", "_isTurret"];
		if (_role == "cargo") exitWith {
			"a3\ui_f\data\igui\cfg\commandbar\imagecargo_ca.paa"
		};
		if (_role == "driver") exitWith {
			if (vehicle _unit isKindOf "Air") then	{
				//no suitable icons for this so we are using a resized one
				"path\to\custom\imagepilot_ca.paa"
			} else {
				"a3\ui_f\data\igui\cfg\commandbar\imagedriver_ca.paa"
			};
		};
		//FFV
		if (_role == "turret" && _isTurret) exitWith {
			"a3\ui_f\data\igui\cfg\simpletasks\types\rifle_ca.paa"
		};
		//gunners and sometimes copilots
		if (_role == "gunner" || (_role == "turret" && !_isTurret)) exitWith {
			"a3\ui_f\data\igui\cfg\commandbar\imagegunner_ca.paa"
		};
		if (_role == "commander") exitWith {
			"a3\ui_f\data\igui\cfg\commandbar\imagecommander_ca.paa"
		};
	};
	""
};