jenkins shared-library dangled images cleaner / images untag, can be used with gcr.io and other docker-compatible registries

DockerCleaner.groovy

class DockerCleaner {
    DockerRegistry dockerRegistry

    DockerCleaner(DockerRegistry dockerRegistry) {
        this.dockerRegistry = dockerRegistry
    }

    ArrayList getImageDangledManifests(String imageName) {
        def imageTags = dockerRegistry.getImageTags(imageName)
        return imageTags.manifest.findAll {
            !it.value.tag
        }.keySet().collect() as ArrayList
    }

    void deleteImageDangledManifests(String imageName, ArrayList manifests = []) {
        ArrayList dangledManifests = manifests ?: getImageDangledManifests(imageName)
        dangledManifests.each { manifest ->
            dockerRegistry.deleteManifest(imageName, manifest as String)
        }
    }
}

DockerRegistry.groovy

import groovy.json.JsonSlurper

class DockerRegistry {
    String apiBaseUrl
    String apiToken

    DockerRegistry(String apiBaseUrl, String apiToken) {
        this.apiBaseUrl = apiBaseUrl
        this.apiToken = apiToken
    }

    HashMap getCatalog() {
        URL url = new URL(this.apiBaseUrl + "_catalog/")
        URLConnection uc = url.openConnection()
        uc.setRequestProperty("Authorization", "Bearer ${apiToken}")
        
        HashMap catalog = [
            "repositories" : []
        ]
        HashMap catalogPart = new JsonSlurper().parseText(
            uc.getInputStream().getText()
        ) as HashMap

        catalog.repositories.addAll(catalogPart.repositories)

        while (catalogPart.next) {
            url = new URL(catalogPart.next)
            uc = url.openConnection()
            uc.setRequestProperty("Authorization", "Bearer ${apiToken}")
            catalogPart = new JsonSlurper().parseText(
                uc.getInputStream().getText()
            ) as HashMap
            catalog.repositories.addAll(catalogPart.repositories)
        }

        return catalog
    }

    HashMap untagImage(String imageName, String tagName) {
        deleteManifest(imageName, tagName)
    }

    HashMap deleteManifest(String imageName, String manifestName) {
        URL url = new URL(this.apiBaseUrl + imageName + "/manifests/" + manifestName)
        HttpURLConnection uc = (HttpURLConnection) url.openConnection()
        uc.setRequestProperty("Authorization", "Bearer ${apiToken}")
        uc.setRequestMethod("DELETE")
        return new JsonSlurper().parseText(
                uc.getInputStream().getText()
        ) as HashMap
    }
}

Scripted pipeline usage example:

import com.example.docker.DockerCleaner
import com.example.docker.DockerRegistry

String apiBaseUrl = "https://gcr.io/v2/"
String apiToken = "xxx"

DockerRegistry gcrRegistry = new DockerRegistry(apiBaseUrl, apiToken)
DockerCleaner cleaner = new DockerCleaner(gcrRegistry)

def catalog = gcrRegistry.getCatalog()
catalog.repositories.each {
    def dangledManifests = cleaner.getImageDangledManifests(it)
    println("Image: ${it}, dangled manifests: ${dangledManifests}")
    if (dangledManifests) {
        println("Dangled manifests found, removing..")
        cleaner.deleteImageDangledManifests(it, dangledManifests)
    }
}