Set KeyCombination accelerators for menu items in QuPath v0.3.2

QuPath-Set accelerators for menu items.groovy

/**
 * QuPath script to set accelerators for specific menu items.
 * 
 * Written for QuPath v0.3.2
 * In answer to https://forum.image.sc/t/feature-request-windows-with-favorite-menu-items/72721/3
 *
 * @author Pete Bankhead
 */

def combos = [
    'Analyze>Density maps>Create density map': 'shortcut+p',
    'Classify>Object classification>Create single measurement classifier': 'shortcut+shift+1'
]

// Set to the menu items
Platform.runLater {
    for (def entry : combos.entrySet()) {
        def mi = getQuPath().lookupMenuItem(entry.getKey())
        def combo = javafx.scene.input.KeyCombination.keyCombination(entry.getValue())
        // Bind accelerator to action if possible
        def action = mi.getProperties().values().find(a -> a instanceof org.controlsfx.control.action.Action)
        if (action != null) {
            action.setAccelerator(combo)
            // Register in QuPath (might not be needed)
            getQuPath().registerAccelerator(action)
        } else {
            mi.acceleratorProperty().unbind() // Just in case
            mi.setAccelerator(combo)
        }
        // Seems necessary in Windows to get it working
        def menu = mi.getParentMenu()
        def items = menu.getItems()
        int ind = items.indexOf(mi)
        items.remove(mi)
        items.add(ind, mi)
    }
}