A twist on the Rubocop linter customised to work with govuk-ruby-lint

govuk-ruby-lint.vim

" Author: ynonp - https://github.com/ynonp, Eddie Lebow https://github.com/elebow
" Description: RuboCop, a code style analyzer for Ruby files

call ale#Set('ruby_rubocop_executable', 'govuk-lint-ruby')
call ale#Set('ruby_rubocop_options', '')

function! ale_linters#ruby#rubocop#GetCommand(buffer) abort
    let l:executable = ale#Var(a:buffer, 'ruby_rubocop_executable')

    return ale#ruby#EscapeExecutable(l:executable, 'govuk-lint-ruby')
    \   . ' --format json --force-exclusion '
    \   . ale#Var(a:buffer, 'ruby_rubocop_options')
    \   . ' --stdin ' . ale#Escape(expand('#' . a:buffer . ':p'))
endfunction

function! ale_linters#ruby#rubocop#GetType(severity) abort
    if a:severity is? 'convention'
    \|| a:severity is? 'warning'
    \|| a:severity is? 'refactor'
        return 'W'
    endif

    return 'E'
endfunction

call ale#linter#Define('ruby', {
\   'name': 'govuk-lint-ruby',
\   'executable': {b -> ale#Var(b, 'ruby_rubocop_executable')},
\   'command': function('ale_linters#ruby#rubocop#GetCommand'),
\   'callback': 'ale#ruby#HandleRubocopOutput',
\})