Create a revision for file

build.gradle.kts

fun digest(file: File, algorithm: String): String {
    val contents = file.readBytes()
    val messageDigest = MessageDigest.getInstance(algorithm)
    val digestBytes = messageDigest.digest(contents)

    return String.format("%032x", BigInteger(1, digestBytes)).substring(0..9)
}

project(":jetpack").configure {
    apply(plugin = "com.github.johnrengelman.shadow")

    tasks.register("rev") {
        group = "build"
        description = "Append revision to output jar"

        val shadowJar by tasks.getting(ShadowJar::class)

        dependsOn(shadowJar)
        inputs.files(shadowJar)
        outputs.dir(shadowJar.destinationDir)

        doLast {
            copy {
                val singleFile = shadowJar.outputs.files.singleFile
                val hash = digest(file(singleFile), "SHA-256")
                from(singleFile)
                into(shadowJar.destinationDir)
                include("*-all.jar")
                rename("(.+)-all.jar", "$1-$hash-all.jar")
            }
        }
    }
}