gradle configuration for a module depending on a prebuilt native library - using gradle-experimental:0.6.0+ plugin.

build.gradle

apply plugin: 'com.android.model.library'

model {

    repositories {
        libs(PrebuiltLibraries) {
            mydependency {
                headers.srcDir "src/main/jni/prebuilts/include"
                binaries.withType(SharedLibraryBinary) {
                    sharedLibraryFile = file("src/main/jni/prebuilts/${targetPlatform.getName()}/libmydependency.so")
                }
            }
        }
    }

    android {
        compileSdkVersion = 23
        buildToolsVersion = "23.0.2"

        defaultConfig.with {
            minSdkVersion.apiLevel = 15
            targetSdkVersion.apiLevel = 23
        }
    }

    android.ndk {
        moduleName = "mylib"
        ldLibs.addAll(['log'])
        cppFlags.add("-std=c++11")
        cppFlags.add("-fexceptions")
        stl = 'gnustl_shared'
        platformVersion = 15
    }

    android.sources {
        main {
            jni {
                dependencies {
                    library "mydependency" linkage "dynamic"
                }
            }
        }
    }
}

cc @proppy
thanks to @rschiu for the pointers!