ファイル分割

divide.scm

#!/usr/bin/env gosh

(use util.match)
(use file.util)
(use gauche.sequence)

(define (usage program)
  (print #`"usage: ,|program| filename num..."))

(define (main args)
  (match args
    ((_ filename . rest)
     (for-each-with-index 
      (lambda (i lines) 
	(unless (null? lines) 
	  (for-each-print-to-file #`",|filename|-,|i|" lines)))
      (divide (file->string-list filename) 
	      (if (string? rest) 
		  (string->integer-list rest) 
		  (map x->integer rest)))))
    ((program . _) (usage program))))

(define (for-each-print-to-file filename ls)
  (with-output-to-file filename
    (lambda () (for-each print ls))))

(define (string->integer-list input)
  (with-input-from-string input
    (lambda ()
      (port-map (lambda (x) (if (integer? x) x (error #`",|x| is not integer"))) 
		read))))

(define (divide ls number-list)
  (receive (mapped rest)
      (map-accum (lambda (size start)
		   (let ((end (+ start size)))
		     (values (subseq ls start end) end)))
		 0
		 (remove (cut = 0 <>) number-list))
    (append mapped (list (subseq ls rest)))))