nix overlay for the creation of mac applications

default.nix

# overlays/pkgs/osx/dash/default.nix
{ pkgs }:

with pkgs; osx.mkAppDerivation rec {
  name = "Dash";
  sourceRoot = "Dash.app";
  src = fetchurl {
    url = "https://kapeli.com/downloads/v4/Dash.zip";
    sha256 = "073fzga9gra5rln7cixj50h7c6zgajhd2jibslkx2qrdbry67mc4";
  };
  meta = {
    version = "4.1.3";
    description = "API Documentation Browser and Code Snippet Manager";
    homepage = https://kapeli.com/dash;
  };
}

mkAppDerivation.nix

# overlays/mkAppDerivation.nix
self: super:

let

  mkAppDerivation =
    { name
    , ...
  } @ args:
    let
      drvName =
        let
          root = builtins.replaceStrings [ " " ] [ "-" ] name;
          suffix =
            if (super.lib.hasAttrByPath [ "meta" "version" ] args)
            then ''-${super.lib.getAttrFromPath [ "meta" "version" ] args}''
            else "";
        in "${root}${suffix}";
    in with super; stdenv.mkDerivation (args // {
      name = drvName;
      buildInputs = [ undmg unzip ];
      phases = [ "unpackPhase" "installPhase" "fixupPhase" ];
      installPhase = ''
        mkdir -p "$out/Applications/${name}.app"
        cp -pR * "$out/Applications/${name}.app"
      '';
    });

in rec {

  osx = {
    inherit mkAppDerivation;
  };

}

pkgs.nix

# overlays/pkgs.nix
self: super:

rec {
  
  dash = super.callPackage ./pkgs/osx/dash { };
  
}