arduino sketch for ESP32 BLE blood pressure client

ble_client.ino

/**
 * A BLE client example that is rich in capabilities.
 * There is a lot new capabilities implemented.
 * author unknown
 * updated by chegewara
 * adapted/extended by planetar
 */
/*

Forming a connection to fb:1e:94:fc:23:84
 - Created client
 - Connected to server
 - Found our service
 - Found our characteristic
We are now connected to the BLE Server.
Setting new characteristic value to "Time since boot: 4"
lup
Setting new characteristic value to "Time since boot: 5"
Notify callback for characteristic 00002a35-0000-1000-8000-00805f9b34fb of data length 19
data: 1E BA 0 71 0 95 0 E7 7 3 E E 3A 0 6E 0 1 0 0 

yep!
1E    30    flags
00BA  186   systolic
0071  113   diastolic
0095  149 arterieller Druck (Mittel)
07E7  2023  Jahr 
03    3     Monat
0E    14    Tag
oE    14    Stunde
3A    54    Minuten
00    0     Sekunden
006E  110   Puls
01    1     UserID
0000  0     Flags

 */
#include "BLEDevice.h"
//#include "BLEScan.h"

// The remote service we wish to connect to.
static BLEUUID serviceUUID("00001810-0000-1000-8000-00805f9b34fb");
// The characteristic of the remote service we are interested in.
static BLEUUID    charUUID("00002A35-0000-1000-8000-00805f9b34fb");

static boolean doConnect = false;
static boolean connected = false;
static boolean doScan = false;
static BLERemoteCharacteristic* pRemoteCharacteristic;
static BLEAdvertisedDevice* myDevice;

static void notifyCallback(
  BLERemoteCharacteristic* pBLERemoteCharacteristic,
  uint8_t* pData,
  size_t length,
  bool isNotify) {
    Serial.print("Notify callback for characteristic ");
    Serial.print(pBLERemoteCharacteristic->getUUID().toString().c_str());
    Serial.print(" of data length ");
    Serial.println(length);
    Serial.print("data: ");
    
    // jetzt byte f byte
    for (int i = 0; i < length; i++) {
      Serial.print(pData[i], HEX);
      Serial.print(" "); //separate values with a space
    }

    // aufloesung
    
    int flag1 = pData[0];
    int syst  = pData[2]*256 + pData[1];
    int diast = pData[4]*256 + pData[3];
    int arter = pData[6]*256 + pData[5];
    int year  = pData[8]*256 + pData[7];
    int month = pData[9];
    int day   = pData[10];
    int hour  = pData[11];
    int minu  = pData[12];
    int sec   = pData[13];
    int puls  = pData[15]*256 + pData[14];
    int user  = pData[16];
    int flag2 = pData[18]*256 + pData[17];
 
    Serial.println();

    Serial.print("flag1: ");
    Serial.println(flag1);
        
    Serial.print("syst: ");
    Serial.println(syst);
 
    Serial.print("diast: ");
    Serial.println(diast);
     
    Serial.print("arter: ");
    Serial.println(arter);
     
    Serial.print("year: ");
    Serial.println(year);
     
    Serial.print("month: ");
    Serial.println(month);
     
    Serial.print("day: ");
    Serial.println(day);
    
    Serial.print("hour: ");
    Serial.println(hour);
    
    Serial.print("minu: ");
    Serial.println(minu);

    Serial.print("sec: ");
    Serial.println(sec);    
     
    Serial.print("puls: ");
    Serial.println(puls);
    
    Serial.print("flag2: ");
    Serial.println(flag2);
    
    
    //Serial.write(pData, length);
    Serial.println();
}

class MyClientCallback : public BLEClientCallbacks {
  void onConnect(BLEClient* pclient) {
  }

  void onDisconnect(BLEClient* pclient) {
    connected = false;
    Serial.println("onDisconnect");
  }
};

bool connectToServer() {
    Serial.print("Forming a connection to ");
    Serial.println(myDevice->getAddress().toString().c_str());
    
    BLEClient*  pClient  = BLEDevice::createClient();
    Serial.println(" - Created client");

    pClient->setClientCallbacks(new MyClientCallback());

    // Connect to the remove BLE Server.
    pClient->connect(myDevice);  // if you pass BLEAdvertisedDevice instead of address, it will be recognized type of peer device address (public or private)
    Serial.println(" - Connected to server");
    pClient->setMTU(517); //set client to request maximum MTU from server (default is 23 otherwise)
  
    // Obtain a reference to the service we are after in the remote BLE server.
    BLERemoteService* pRemoteService = pClient->getService(serviceUUID);
    if (pRemoteService == nullptr) {
      Serial.print("Failed to find our service UUID: ");
      Serial.println(serviceUUID.toString().c_str());
      pClient->disconnect();
      return false;
    }
    Serial.println(" - Found our service");


    // Obtain a reference to the characteristic in the service of the remote BLE server.
    pRemoteCharacteristic = pRemoteService->getCharacteristic(charUUID);
    if (pRemoteCharacteristic == nullptr) {
      Serial.print("Failed to find our characteristic UUID: ");
      Serial.println(charUUID.toString().c_str());
      pClient->disconnect();
      return false;
    }
    Serial.println(" - Found our characteristic");

    // Read the value of the characteristic.
    if(pRemoteCharacteristic->canRead()) {
      std::string value = pRemoteCharacteristic->readValue();
      Serial.print("The characteristic value was: ");
      Serial.println(value.c_str());
    }

    if(pRemoteCharacteristic->canNotify())
      pRemoteCharacteristic->registerForNotify(notifyCallback);

    // hier ist meins
    
    if(pRemoteCharacteristic->canIndicate()){
      pRemoteCharacteristic->registerForNotify(notifyCallback);
      Serial.println(" - Registered Callback"); 
      const uint8_t indicationOn[] = {0x2, 0x0};
      pRemoteCharacteristic->getDescriptor(BLEUUID((uint16_t)0x2902))->writeValue((uint8_t*)indicationOn, 2, true);
      Serial.println(" - Enabled Indication");    
    }

    connected = true;
    return true;
}
/**
 * Scan for BLE servers and find the first one that advertises the service we are looking for.
 */
class MyAdvertisedDeviceCallbacks: public BLEAdvertisedDeviceCallbacks {
 /**
   * Called for each advertising BLE server.
   */
  void onResult(BLEAdvertisedDevice advertisedDevice) {
    Serial.print("BLE Advertised Device found: ");
    Serial.println(advertisedDevice.toString().c_str());

    // We have found a device, let us now see if it contains the service we are looking for.
    if (advertisedDevice.haveServiceUUID() && advertisedDevice.isAdvertisingService(serviceUUID)) {

      BLEDevice::getScan()->stop();
      myDevice = new BLEAdvertisedDevice(advertisedDevice);
      doConnect = true;
      doScan = true;

    } // Found our server
  } // onResult
}; // MyAdvertisedDeviceCallbacks


void setup() {
  Serial.begin(115200);
  Serial.println("Starting Arduino BLE Client application...");
  BLEDevice::init("");

  // Retrieve a Scanner and set the callback we want to use to be informed when we
  // have detected a new device.  Specify that we want active scanning and start the
  // scan to run for 5 seconds.
  BLEScan* pBLEScan = BLEDevice::getScan();
  pBLEScan->setAdvertisedDeviceCallbacks(new MyAdvertisedDeviceCallbacks());
  pBLEScan->setInterval(1349);
  pBLEScan->setWindow(449);
  pBLEScan->setActiveScan(true);
  pBLEScan->start(5, false);
} // End of setup.


// This is the Arduino main loop function.
void loop() {
Serial.println("lup");
  // If the flag "doConnect" is true then we have scanned for and found the desired
  // BLE Server with which we wish to connect.  Now we connect to it.  Once we are 
  // connected we set the connected flag to be true.
  if (doConnect == true) {
    if (connectToServer()) {
      Serial.println("We are now connected to the BLE Server.");
    } else {
      Serial.println("We have failed to connect to the server; there is nothin more we will do.");
    }
    doConnect = false;
  }

  // If we are connected to a peer BLE Server, update the characteristic each time we are reached
  // with the current time since boot.
  if (connected) {
    String newValue = "Time since boot: " + String(millis()/1000);
    //Serial.println("Setting new characteristic value to \"" + newValue + "\"");
    
    // Set the characteristic's value to be the array of bytes that is actually a string.
    pRemoteCharacteristic->writeValue(newValue.c_str(), newValue.length());

    
  }else if(doScan){
    BLEDevice::getScan()->start(0);  // this is just example to start scan after disconnect, most likely there is better way to do it in arduino
  }
  
  delay(1000); // Delay a second between loops.
} // End of loop