Doing key lookup in Clojure

lookup.clj

;; If it's a record-like thing then we want to emphasize 
;; that it's a key-lookup, so use (:key coll)
(:uri req)
(:email member)


;; Some collections behave more like functions, here use (coll key), 
;; that way someone reading the code without context can understand it, 
;; without having to know that it's really a map or set
(def allowed-role? #{:admin :mod})
(allowed-role? (:role user))

(def message-color {:error "red" :warning "orange" :success "green"})
(let [{:keys [content type]} message]
  [:p {:style {:background-color (message-color type)}}
   content])


;; This also makes it clear that you can use functional composition
(def has-access? (comp allowed-role? :role))
(has-access? user)


;; If both collection and key are variables, then (get coll key) 
;; can help keep things readable, because it's explicit about 
;; the roles of its arguments
(def flags {:f "-format" :d "-duration"})

(defn cli-args [opts]
  (for [[k v] opts]
    (str (get flags k) " " v)))