NamedThreadFactory in Java and Groovy style

NamedThreadFactory.groovy

import java.util.concurrent.ThreadFactory
import java.util.concurrent.atomic.AtomicInteger

// --- Java Style ---

class NamedThreadFactory implements ThreadFactory {
    
    private final String prefix
    private final AtomicInteger count
    
    NamedThreadFactory(String prefix) {
        if (!prefix?.trim()) {
            throw new IllegalArgumentException("Cannot create $NamedThreadFactory without a base name. Provided prefix is: '$prefix'")
        }
        
        this.prefix = prefix
        this.count = new AtomicInteger(0)
    }
    
    Thread newThread(Runnable runnable) {
        new Thread(runnable, "${prefix}-${count.getAndIncrement()}")
    }
}

def jtf = new NamedThreadFactory('foobar')
def jt = jtf.newThread { println 'Hello, world!' }

// --- Groovy Style ---

threadFactory = [
    prefix    : 'foobar', 
    count     : new AtomicInteger(0), 
    newThread : { Runnable r -> new Thread(r, "${threadFactory.prefix}-${threadFactory.count.getAndIncrement()}") }
]

gtf = threadFactory as ThreadFactory
def gt = gtf.newThread { println 'Hello, world!' }

jt.start()
gt.start()