Martin Odersky's Phone Coder example translated into Clojure

coder.clj

(use '[clojure.string :only (join)])


(defn coder
  [dictionary]
  (let [mnemonics {\2 "ABC" \3 "DEF" \4 "GHI" \5 "JKL", 
                   \6 "MNO" \7 "PQRS" \8 "TUV" \9 "WXYZ"}
        char-code (into {} (mapcat (fn [[n cs]]
                                     (map #(vector % n) cs))
                                   mnemonics))
        word-code (fn [word]
                    (join (map char-code (.toUpperCase word))))
        words-for-number (group-by word-code dictionary)
        encode (fn encode [number]
                 (if (empty? number)
                   #{()}
                   (set (for [split (range 1 (inc (count number)))
                              word (words-for-number (join (take split number)))
                              xs (encode (join (drop split number)))]
                          (cons word xs)))))]
    (fn [number]
      (map (partial join " ") (encode number)))))

(def dictionary
  (set (with-open [rdr (clojure.java.io/reader "/usr/share/dict/words")]
         (doall (filter #(re-matches #"[a-zA-Z]+" %)
                        (filter #(> (count %) 1) (line-seq rdr)))))))

(def translate
  (coder (conj dictionary "Scala" "rocks")))

(translate "7225276257")