dependencies.pl

use v5.28;
use warnings;
use experimental qw( signatures postderef );
use version;

use Data::Printer;
use MetaCPAN::Client;

my $mcpan = MetaCPAN::Client->new;
my ( $dist, $version ) = @ARGV;

my $search_spec = {
        all => [
                { distribution => $dist },
                ( { version => $version } )x!!$version,
        ],
};

p( $search_spec );

my $rs = $mcpan->release( $search_spec );
while ( my $release = $rs->next ) {
        my @dependencies = $release->dependency->@*;
        for my $dependency ( @dependencies ) {
                say sprintf "%s (%s) depends on %s (%s)",
                        $release->distribution,
                        $release->version,
                        $dependency->{module},
                        $dependency->{version} || '<any>',
                        ;
                my $dep_ver = version->parse( $dependency->{version} )->numify;
                my $dep_rs = $mcpan->all( 'module', {
                        es_filter => {
                                and => [
                                        { term => { name => $dependency->{module} } },
                                        { range => { version_numified => { gte => $dep_ver } } },
                                ],
                        },
                });
                while ( my $dep_module = $dep_rs->next ) {
                        say sprintf "Dependency %s (%s) will satisfy %s (%s)",
                                $dep_module->distribution,
                                $dep_module->version,
                                $dependency->{module},
                                $dependency->{version} || '<any>',
                                ;
                }
        }
}