gistfile1.scpt

on open theseFiles
	set listSize to count of theseFiles
	set counter to 1
	set results to ""
	tell application id "com.Growl.GrowlHelperApp"
		set the allNotificationsList to {"Uploaded"}
		set the enabledNotificationsList to {"Uploaded"}
		register as application "PicasaUploader" all notifications allNotificationsList default notifications enabledNotificationsList icon of application "Script Editor"
		notify with name "Uploaded" title "Start Picasa Upload" description "( " & listSize & " )  File(s)" application name "PicasaUploader"
		repeat with thisFile in theseFiles
			set theFileName to POSIX path of (thisFile)
			set myResult to do shell script "export PERLBREW_HOME=~/perl5/perlbrew; source ~/perl5/perlbrew/etc/bashrc;$HOME/bin/picasa-upload.pl " & quoted form of theFileName
			
			notify with name "Uploaded" title "Uploaded" description "(" & counter & "/" & listSize & ")" & theFileName application name "PicasaUploader"
			set results to results & myResult & return
			set counter to counter + 1
			
		end repeat
		set the clipboard to ((results) as text)
		notify with name "Uploaded" title "Uploaded" description "" & listSize & " Files are uploaded" application name "PicasaUploader"
	end tell
end open