QUCS-S 0.0.23 derivation

qucs-s.nix

{ stdenv, lib, fetchFromGitHub, flex, bison, qtbase, qtscript, libX11, cmake, gperf, adms,
  ngspice, wrapQtAppsHook, kernels ? [ ngspice ] }:

stdenv.mkDerivation rec {
  pname = "qucs-s";
  version = "0.0.23";

  src = fetchFromGitHub {
    owner = "ra3xdh";
    repo = "qucs_s";
    rev = version;
    sha256 = "1zbqwvmsgxygiryn5qr7zgicfjzq4qq8gc0vmpzy23zgpzf4px0j";
  };

  nativeBuildInputs = [ wrapQtAppsHook cmake ];
  buildInputs = [ flex bison qtbase qtscript libX11 gperf adms ] ++ kernels;

  qtWrapperArgs = [ "--prefix PATH : ${lib.makeBinPath kernels}" ];

  doInstallCheck = true;
  installCheck = ''
    $out/bin/qucs-s --version
  '';

  meta = with lib; {
    description = "Spin-off of Qucs that allows custom simulation kernels";
    longDescription = ''
      Spin-off of Qucs that allows custom simulation kernels.
      Default version is installed with ngspice.
    '';
    homepage = "https://ra3xdh.github.io/";
    license = licenses.gpl2Plus;
    maintainers = with maintainers; [ mazurel ];
    platforms = with platforms; linux;
  };
}