Jira Script Runner - Behaviour - Issue Templates, Restrict Links Types

jira_script runner_behaviour.groovy

// ------------------------------------------
// ---- Set default Description -------------
// ------------------------------------------

def defaultDescriptions = [
    Story: """
      *As a* USER
      *I want* FEATURE
      *so that* BENEFIT
      
      h4. Acceptance Criterias
      # NONE

      h4. Infos
      * NONE
      """
]

if (! underlyingIssue?.description) {
  getFieldById("description")?.formValue = defaultDescriptions[issueContext.issueType.name]?.stripIndent()
}


// ------------------------------------------
// ---- Set Allowed Link Types --------------
// ------------------------------------------
import com.atlassian.jira.component.ComponentAccessor
import com.atlassian.jira.issue.link.IssueLinkTypeManager

def allowedLinkNames = [
    // --- Jira Defaults ---
    "relates to", "relates to",
    "duplicates", "is duplicated by",
    "blocks", "is blocked by",
    "clones", "is cloned by",
]

def  allowedLinks = ComponentAccessor.getComponent(IssueLinkTypeManager).getIssueLinkTypes(false)
  .findAll { it.outward in allowedLinkNames || it.inward in allowedLinkNames }
getFieldById("issuelinks-linktype").setFieldOptions(allowedLinks.collectEntries {
    [ (it.outward): it.outward, (it.inward): it.inward ]
})


// ------------------------------------------
// ---- Set Allowed Resolutions -------------
// ------------------------------------------
import com.atlassian.jira.component.ComponentAccessor

def allowedResolutionNames = [
    // --- Jira Defaults ---
    "Fixed",
    "Duplicate",
    "Won't Fix",
    "Incomplete",
    "Cannot Reproduce",
]

def allowedResolutions = ComponentAccessor.constantsManager.resolutions
  .findAll { it.name in allowedResolutionNames }
getFieldById("resolution").setFieldOptions(allowedResolutions.collect {
    it.name
})