A simple example of mapping a Haskell field to multiple columns in Orville

RelationalMapExample.hs

module RelationalMapExample where

import qualified Data.Int as Int
import qualified Data.Text as Text

import qualified Database.Orville as O

data Update key = Update
  { updateId :: key
  , updateLocation :: Text.Text
  , updateStatus :: UpdateStatus
  }

data UpdateStatus = UpdateStatus
  { updateStatusCode :: Int.Int32
  , updateStatusDescription :: Text.Text
  } deriving (Eq, Show)

updateStatusTable :: O.TableDefinition (Update Int) (Update ()) Int
updateStatusTable =
  O.mkTableDefinition $
  O.TableParams
    { O.tblName = "update"
    , O.tblPrimaryKey = updateIdField
    , O.tblMapper =
        Update
          <$> O.readOnlyField updateIdField
          <*> O.attrField updateLocation (O.textField "location" 255)
          <*> O.mapAttr updateStatus updateStatusMap
    , O.tblGetKey = updateId
    , O.tblSafeToDelete = []
    , O.tblComments = O.noComments
    }

updateIdField :: O.FieldDefinition Int
updateIdField = O.automaticIdField "id" `O.withFlag` O.PrimaryKey

updateStatusMap :: O.RelationalMap UpdateStatus UpdateStatus
updateStatusMap =
  UpdateStatus
    <$> O.attrField updateStatusCode (O.int32Field "status_code")
    <*> O.attrField updateStatusDescription (O.textField "status_description" 255)